Каскодный усилитель

Хотя усилитель с ОБ (с общей базой) известен большей широкополосностью по сравнению со схемой с ОЭ (с общим эмиттером), для многих приложений низкое входное сопротивление (десятки Ом) схемы с ОБ является ограничением. Решение заключается в том, чтобы перед каскадом с ОБ с низким коэффициентом усиления поставить каскад с ОЭ, который обладает высоким входным сопротивлением (килоомы). Смотрите рисунок ниже. Каскады каскодной схемы включены последовательно, а не каскадно, как в стандартной схеме усилителя. Для примера каскадного усилителя смотрите схему «Разделительные конденсаторы, объединяющие три усилительных каскада с общим эмиттером» в последующем разделе «Соединение входов и выходов» данной главы. Схема каскодного усилителя обладает и широкополосностью, и умеренно высоким входным сопротивлением.

Ключом к пониманию широкополосности каскодной схемы является эффект Миллера. Эффект Миллера – это умножение широкополосной ёмкости коллектор-база на коэффициент усиления по напряжению A_V. Эта емкость коллектор-база меньше емкости эмиттер-база. Таким образом, можно было бы подумать, что емкость коллектор-база будет оказывать слабое влияние. Однако в схеме с общим эмиттером выходной сигнал на коллекторе противоположен по фазе входному сигналу на базе. Сигнал на коллекторе противодействует через емкостную обратную связь сигналу на базе. Кроме того, обратная связь коллектора в (1 – A_V) больше сигнала на базе. Имейте в виду, что A_V является отрицательным числом для инвертирующего усилителя с общим эмиттером. Таким образом, небольшая емкость коллектор-база становится в (1 + |A_V|) больше, чем ее фактическое значение. Это увеличение емкости уменьшает обратную связь по мере увеличения частоты, уменьшая отклик на высоких частотах у усилителя с общим эмиттером.

Примерный коэффициент усиления по напряжению усилителя с общим эмиттером на рисунке ниже равен –R_нагр/r_Э. Ток эмиттера с помощью смещения установлен на 1,0 мА. r_Э = 26мВ/I_Э = 26мВ/1.0мА = 26 Ом. Таким образом, A_V = –R_нагр/r_Э = –4700/26 = -181. В техническом описании pn2222 указано C_КБ = 8 пФ. Емкость Миллера равна C_КБ(1 – A_V). Коэффициент усиления A_V = -181, отрицательное значение, так как это инвертирующий усилитель. C_Миллер = C_КБ(1 – A_V) = 8пФ(1 – (–181)) = 1456пФ.

Схема с общей базой не зависит от эффекта Миллера, поскольку заземленная база экранирует сигнал коллектора от подачи обратно на эмиттерный вход. Таким образом, усилитель с общей базой обладает более высокочастотной характеристикой. При этом по-прежнему желательно использование каскада с общим эмиттером для получения относительно высокого входного сопротивления. Цель состоит в том, чтобы уменьшить коэффициент усиления каскада с общим эмиттером (до примерно 1), что уменьшит эффект Миллера обратной связи коллектор-база до 1 · C_КБ. Суммарная емкость обратной связи коллектор-база равна емкости обратной связи 1 · C_КБ плюс реальная емкость C_КБ, что в итоге дает 2 · C_КБ. Это дает значительное уменьшение со значения 181 · C_КБ. Емкость Миллера для коэффициента усиления –2 каскада с общим эмиттером равна C_Миллер = C_КБ(1 – A_V) = C_КБ(1 – (–1)) = C_КБ · 2.

Способ уменьшения коэффициента усиления схемы с общим эмиттером заключается в уменьшении сопротивления нагрузки. Коэффициент усиления по напряжению усилителя с общим эмиттером примерно равен R_К/R_Э. Внутреннее сопротивление r_Э при токе эмиттера 1 мА составляет 26 Ом. Расчет r_Э смотрите выше. Нагрузка коллектора R_К представляет собой сопротивление эмиттера каскада с общей базой, который является нагрузкой каскада с общим эмиттером, и это снова 26 Ом. Коэффициент усиления каскада с общим эмиттером примерно равен A_V = R_К/R_Э = 26/26 = 1. Емкость Миллера равна C_Миллер = C_КБ(1 – A_V) = 8пФ(1 – (–1)) = 16пФ. Теперь мы имеем относительно высокое входное сопротивление каскада с общим эмиттером, устранив влияние эффекта Миллера, однако без усиления по напряжению. Каскад с общей базой обеспечивает высокий коэффициент усиления по напряжению, A_V = –181. Коэффициент усиления по току каскодной схемы равен β для каскада с общим эмиттером и 1 для каскада с общей базой, что в итоге дает β. Таким образом, каскодная схема имеет относительно высокое входное сопротивление схемы с общим эмиттером, хорошее усиление и широкую полосу пропускания схемы с общей базой.

На рисунке выше показаны схемы каскодного усилителя и усилителя с общим эмиттером для сравнения в SPICE. Список соединений приведен ниже. Источник переменного напряжения V3 управляет обоими усилителями через узел 4. Резисторы смещения для этой схемы вычисляются в примере каскодной схемы в разделе «Расчеты смещения» этой главы.

Список соединений SPICE для печати входных и выходных переменных напряжений.

*SPICE circuit <03502.eps> from XCircuit v3.20
V1 19 0 10
Q1 13 15 0 q2n2222
Q2 3 2 A q2n2222
R1 19 13 4.7k
V2 16 0 1.5
C1 4 15 10n
R2 15 16 80k
Q3 A 5 0 q2n2222
V3 4 6 SIN(0 0.1 1k)  ac 1
R3 1 2 80k
R4 3 9 4.7k
C2 2 0 10n
C3 4 5 10n
R5 5 6 80k
V4 1 0 11.5
V5 9 0 20
V6 6 0 1.5
.model q2n2222 npn (is=19f bf=150
+ vaf=100 ikf=0.18 ise=50p ne=2.5 br=7.5
+ var=6.4 ikr=12m isc=8.7p nc=1.2 rb=50
+ re=0.4 rc=0.3 cje=26p tf=0.5n
+ cjc=11p tr=7n xtb=1.5 kf=0.032f af=1)
.tran 1u 5m
.AC DEC 10 1k 100Meg
.end  

Осциллограммы на рисунке выше показывают работу каскодного усилителя. Входной сигнал показан умноженным на 10, так чтобы он был виден совместно с выходными сигналами. Обратите внимание, что в каскодной схеме, в каскаде с общим эмиттером, сигнал Va инвертирован относительно входного сигнала. Выходные сигналы и в каскодной схеме, и в усилителе с общим эмиттером имеют большую амплитуду. Точка Va имеет смещение по постоянному напряжению примерно на 10 В, примерно посередине между 20 В и землей. Сигнал больше, чем можно было бы объяснить коэффициентом усиления каскада с общим эмиттером, равным 1. Он в три раза больше, чем ожидалось.

На рисунке выше показаны амплитудно-частотные характеристики каскодной схемы и схемы с общим эмиттером. Операторы SPICE, отвечающие за AC анализ, извлечены из листинга:

V3 4 6 SIN(0 0.1 1k) ac 1 
.AC DEC 10 1k 100Meg 

Обратите внимание, что "ac 1" является обязательным в строке оператора V3. Каскодный усилитель имеет слегка улучшенный коэффициент усиления в середине диапазона. Тем не менее, нам, в основном, интересна ширина полосы пропускания, измеренная на уровне -3 дБ по сравнению с усилением в середине полосы для каждого усилителя. Эти точки показаны на рисунке выше вертикальными сплошными линиями. Также можно распечатать интересующие данные из nutmeg на экран (команда в первой строке):

nutmeg 6 -> print frequency db(vm(3)) db(vm(13))

Index   frequency     db(vm(3))  db(vm(13)) 
22      0.158MHz      47.54      45.41
33      1.995MHz      46.95      42.06
37      5.012MHz      44.63      36.17

Индекс 22 выдает коэффициент усиления в дБ в середине полосы пропускания: для каскодной схемы vm(3) = 47.5 дБ, для схемы с общим эмиттером vm(13) = 45.4 дБ. Из многих напечатанных линий индекс 33 был ближайшим к тому, чтобы он был на 3 дБ ниже 45.4 дБ и равен 42.0 дБ для схемы с общим эмиттером. Соответствующая частота индекса 33 составляет примерно 2 МГц, это ширина полосы пропускания схемы с общим эмиттером. Индекс 37 с vm(3) = 44.6 дБ примерно на 3 дБ ниже 47.5 дБ. Соответствующая частота индекса 37 составляет 5 МГц, это ширина полосы пропускания каскодной схемы. Таким образом, каскодный усилитель имеет более широкую полосу пропускания. Мы не смотрим на уменьшение усиления на нижних частотах. Оно связано с конденсаторами, и его можно устранить, заменив конденсаторы на более большие. Ширина полосы в 5 МГц в нашем примере каскодного усилителя хотя и лучше, чем у схемы с общим эмиттером, не показательна для RF (РЧ, радиочастотного) усилителя. Для повышения верхней частоты полосы пропускания следует использовать пару РЧ или СВЧ транзисторов с более низкими межэлектродными емкостями. До изобретения радиочастотного MOSFET транзистора с двойным затвором каскодный усилитель на биполярных транзисторах можно было найти в дециметровых (UHF) ТВ приемниках.

Подведем итоги:

• Каскодный усилитель состоит из каскада с общим эмиттером, нагруженного каскадом с общей базой.
• Сильно нагруженный каскад с общим эмиттером обладает низким коэффициентом усиления по напряжению, равным 1, что устраняет влияние эффекта Миллера.
• Каскодный усилитель обладает высоким коэффициентом усиления, относительно высоким входным сопротивлением, высоким выходным сопротивлением и широкой полосой пропускания.

Теги