Как работает датчик влажности почвы, и его взаимодействие с Arduino
Когда вы слышите термин «умный сад», вам приходит в голову система, которая измеряет влажность почвы и автоматически поливает ваши растения.
С этим типом системы вы можете поливать растения только при необходимости и избегать чрезмерного или недостаточного полива.
Если вы хотите построить такую систему, вам обязательно понадобится датчик влажности почвы.
Как работает датчик влажности почвы?
Работа датчика влажности почвы довольно проста.
Вилка в форме зонда с двумя открытыми проводниками действует как переменный резистор (потенциометр), сопротивление которого изменяется в зависимости от содержания воды в почве.
Это сопротивление обратно пропорционально влажности почвы:
- большее количество воды в почве означает лучшую проводимость и приводит к снижению сопротивления;
- меньшее количество воды в почве означает худшую проводимость и приводит к повышению сопротивления.
Датчик выдает выходное напряжение в соответствии с сопротивлением, измеряя которое мы можем определить уровень влажности.
Обзор аппаратного обеспечения
Типовой датчик влажности почвы состоит из двух компонентов.
Зонд
Датчик содержит вилочный зонд с двумя открытыми проводниками, который погружается в почву или в любое другое место, где должно измеряться содержание воды.
Как сказано выше, он действует как переменный резистор, сопротивление которого изменяется в зависимости от влажности почвы.
Модуль
Датчик также содержит электронный модуль, который соединяет датчик с Arduino.
В соответствии с сопротивлением датчика модуль выдает выходное напряжение, которое доступно на выводе аналогового выхода (AO).
Этот же сигнал подается на высокоточный компаратор LM393 для его оцифровки, с выхода которого сигнал подается на вывод цифрового выхода (DO).
Для регулировки чувствительности цифрового выхода (DO) модуль содержит встроенный потенциометр.
С помощью этого потенциометра вы можете установить пороговое значение; таким образом, когда уровень влажности превысит пороговое значение, модуль выдаст низкий логический уровень, в остальных случаях на цифровой выход будет подаваться высокий логический уровень.
Эта настройка очень полезна, когда вы хотите инициировать действие при достижении определенного порога. Например, когда уровень влажности в почве пересекает пороговое значение, вы можете активировать реле, чтобы начать перекачивание воды. Вот вам идея!
Совет: поверните движок потенциометра по часовой стрелке, чтобы увеличить чувствительность, или против часовой стрелки, чтобы уменьшить ее.
Помимо этого, модуль имеет два светодиода. Индикатор питания загорится, когда на модуль будет подано напряжение питания. Светодиод состояния загорится, когда на цифровой выход будет подаваться низкий логический уровень.
Распиновка датчика влажности почвы
Датчик влажности почвы очень прост в использовании и содержит только 4 вывода для связи с внешним миром.
AO (аналоговый выход) выдает аналоговый сигнал с напряжением в диапазоне между напряжением питания и 0 В и будет подключен к одному из аналоговых входов нашей платы Arduino.
Вывод DO (цифровой выход) выдает цифровой выходной сигнал со схемы встроенного компаратора. Вы можете подключить его к любому цифровому выводу на Arduino или напрямую к 5-вольтовому реле или подобному устройству.
Вывод VCC подает питание на датчик. Рекомендуется питать датчик напряжением от 3,3 до 5 В. Обратите внимание, что сигнал на аналоговом выходе будет зависеть от того, какое напряжение питания подается на датчик.
GND для подключения земли.
Измерение влажности почвы с помощью аналогового выхода
Поскольку модуль предоставляет как аналоговый, так и цифровой выходные сигналы, то для нашего первого эксперимента мы будем измерять влажность почвы, считывая аналоговые показания.
Подключение
Давайте подключим наш датчик влажности почвы к плате Arduino.
Сначала вам нужно подать питание на датчик. Для этого вы можете подключить вывод VCC на модуле к выводу 5V на Arduino.
Однако одной из широко известных проблем с этими датчиками является их короткий срок службы при воздействии влажной среды. При постоянной подаче питания на зонд скорость коррозии значительно увеличивается.
Чтобы преодолеть эту проблему, мы рекомендуем не подавать питание на датчик постоянно, а включать его только тогда, когда вы снимаете показания.
Самый простой способ сделать это – подключить вывод VCC к цифровому выводу Arduino и устанавливать на нем высокий или низкий логический уровень, когда это необходимо.
Кроме того, итоговая мощность, потребляемая модулем (оба светодиода горят), составляет около 8 мА, поэтому можно запитать модуль от цифрового вывода на Arduino.
Итак, давайте подключим вывод VCC модуля к цифровому выводу 7 Arduino, а вывод GND модуля к выводу GND Arduino.
И, наконец, подключите вывод AO модуля к выводу A0 аналого-цифрового преобразователя Arduino.
Схема соединений показана на рисунке ниже.
Калибровка
Чтобы получить точные показания с датчика влажности почвы, рекомендуется сначала откалибровать его для конкретного типа почвы, которую вы планируете контролировать.
Различные типы почвы могут по-разному влиять на показания датчика, поэтому ваш датчик в зависимости от типа используемой почвы может быть более или менее чувствительным.
Прежде чем вы начнете хранить данные или запускать события, вы должны увидеть, какие показания вы на самом деле получаете от вашего датчика.
Чтобы отметить, какие значения выводит ваш датчик, когда почва максимально сухая, и когда она полностью насыщена влагой, воспользуйтесь скетчем, приведенным ниже.
// Выводы, подключенные к датчику
#define sensorPower 7
#define sensorPin A0
void setup()
{
pinMode(sensorPower, OUTPUT);
// Изначально оставляем датчику выключенным
digitalWrite(sensorPower, LOW);
Serial.begin(9600);
}
void loop()
{
// получить показание из функции ниже и напечатать его
Serial.print("Analog output: ");
Serial.println(readSensor());
delay(1000);
}
// Данная функция возвращает аналоговый результат измерений датчика влажности почвы
int readSensor()
{
digitalWrite(sensorPower, HIGH); // Включить датчик
delay(10); // Дать время питанию установиться
int val = analogRead(sensorPin); // Прочитать аналоговое значение от датчика
digitalWrite(sensorPower, LOW); // Выключить датчик
return val; // Вернуть аналоговое значение влажности
}Когда вы запустите этот скетч, вы увидите похожие значения в мониторе последовательного порта:
- ~ 850, когда почва сухая;
- ~ 400, когда почва полностью насыщена влагой.
Этот тест может потребовать несколько проб и ошибок. Как только вы получите хороший контроль над этими показаниями, вы сможете использовать их в качестве пороговых значений, если намерены инициировать какое-либо действие.
Финальная сборка
Основываясь на значениях калибровки, программа, приведенная ниже, задает следующие диапазоны для определения состояния почвы:
- <500 – слишком влажная;
- 500-750 – это целевой диапазон;
- >750 – достаточно сухая для полива.
/* Измените эти значения, основываясь на своих значениях калибровки */
#define soilWet 500 // Определяет максимальное значение, при котором, мы решили, что почва 'влажная'
#define soilDry 750 // Определяет минимальное значение, при котором, мы решили, что почва 'сухая'
// Выводы, подключенные к датчику
#define sensorPower 7
#define sensorPin A0
void setup()
{
pinMode(sensorPower, OUTPUT);
// Изначально оставляем датчику выключенным
digitalWrite(sensorPower, LOW);
Serial.begin(9600);
}
void loop()
{
// получить показание из функции ниже и напечатать его
int moisture = readSensor();
Serial.print("Analog Output: ");
Serial.println(moisture);
// определить состояние нашей почвы
if (moisture < soilWet)
{ // слишком влажная
Serial.println("Status: Soil is too wet");
}
else if (moisture >= soilWet && moisture < soilDry)
{ // идеальное состояние
Serial.println("Status: Soil moisture is perfect");
}
else
{ // слишком сухая - пора поливать
Serial.println("Status: Soil is too dry - time to water!");
}
delay(1000); // Для проверки берем показания раз в секунду
// Обычно вам необходимо проверять показания, возможно, раз или два в день
Serial.println();
}
// Данная функция возвращает аналоговый результат измерений датчика влажности почвы
int readSensor()
{
digitalWrite(sensorPower, HIGH); // Включить датчик
delay(10); // Дать время питанию установиться
int val = analogRead(sensorPin); // Прочитать аналоговое значение от датчика
digitalWrite(sensorPower, LOW); // Выключить датчик
return val; // Вернуть аналоговое значение влажности
}Если все в порядке, вы должны увидеть вывод в мониторе последовательного порта, похожий на приведенный ниже.
Измерение влажности почвы с помощью цифрового выхода
Для нашего второго эксперимента мы определим состояние почвы с помощью цифрового выхода.
Подключение
Мы будем использовать схему из предыдущего примера. На этот раз нам просто нужно удалить подключение к выводу аналого-цифрового преобразователя и подключить вывод DO модуля к цифровому выводу 8 Arduino.
Соберите схему, как показано ниже:
Калибровка
Для калибровки цифрового выхода (DO) модуль имеет встроенный потенциометр.
Вращая движок этого потенциометра, вы можете установить пороговое значение. Таким образом, когда уровень влажности превысит пороговое значение, светодиод состояния загорится, и модуль выдаст низкий логический уровень.
Теперь, чтобы откалибровать датчик, вставьте зонд в почву, когда ваше растение будет готово к поливу, и подстройте потенциометр по часовой стрелке так, чтобы светодиод состояния горел, а затем подстройте потенциометр обратно против часовой стрелки, пока светодиод не погаснет.
Теперь ваш датчик откалиброван и готов к использованию.
Код Arduino
После того, как схема будет собрана, загрузите в Arduino следующий скетч.
// Выводы, подключенные к датчику
#define sensorPower 7
#define sensorPin 8
void setup()
{
pinMode(sensorPower, OUTPUT);
// Изначально оставляем датчику выключенным
digitalWrite(sensorPower, LOW);
Serial.begin(9600);
}
void loop()
{
// получить показание из функции ниже и напечатать его
int val = readSensor();
Serial.print("Digital Output: ");
Serial.println(val);
// Определить статус ситуации с влажностью почвы
if (val)
{ // слишком сухая - пора поливать
Serial.println("Status: Soil is too dry - time to water!");
}
else
{ // идеальное состояние
Serial.println("Status: Soil moisture is perfect");
}
delay(1000); // Для проверки берем показания раз в секунду
// Обычно вам необходимо проверять показания, возможно, каждые 12 часов
Serial.println();
}
// Данная функция цифровой результат измерений датчика влажности почвы
int readSensor()
{
digitalWrite(sensorPower, HIGH); // Включить датчик
delay(10); // Дать время питанию установиться
int val = digitalRead(sensorPin); // Прочитать цифровое значение от датчика
digitalWrite(sensorPower, LOW); // Выключить датчик
return val; // Вернуть цифровое значение влажности
}Если все в порядке, вы должны увидеть вывод в мониторе последовательного порта, похожий на приведенный ниже.
