Как работает акселерометр? Взаимодействие ADXL335 с Arduino

Добавлено 9 декабря 2019 в 02:16

Вы когда-нибудь задумывались, как ваш смартфон отличает верх от низа? Это одна из самых классных функций современных смартфонов. У всех из них есть встроенное в схему крошечное устройство под названием акселерометр, которое может понимать, когда вы наклоняете его с одной стороны на другую. Таким образом, ваш смартфон автоматически определяет, когда нужно переключить положение экрана с портретного на альбомное.

Как работает акселерометр? Взаимодействие ADXL335 с Arduino
Как работает акселерометр? Взаимодействие ADXL335 с Arduino

Акселерометры широко используются в чувствительных к движению и наклону приложениях с низким энергопотреблением, таких как мобильные устройства, игровые системы, защита дисков, стабилизация изображений, спортивные и медицинские устройства.

Давайте внимательнее посмотрим, что это, что они делают, и как работают.

Что такое ускорение?

Блестящий ученый Исаак Ньютон в своем втором законе движения определил ускорение, связав его с массой и силой.

Если у вас есть определенная сила (скажем, сила в вашей ноге, когда вы пинаете ею), и вы применяете ее к массе (футбольный мяч), вы заставляете массу ускоряться (мяч отлетит в воздухе).

Сила = Масса х Ускорение

Ускорение = Сила / Масса

Другими словами, ускорение – это количество силы, которое нам нужно для перемещения каждой единицы массы.

Как работает акселерометр?

Чтобы узнать, как работают акселерометры, полезно представить шар внутри трехмерного куба.

Рисунок 1 Невесомость
Рисунок 1 – Невесомость

Предположим, что куб находится в космическом пространстве, где всё находится в невесомом состоянии, шар просто будет плавать в середине куба.

Теперь давайте представим, что каждая стена представляет определенную ось.

Если мы внезапно переместим куб влево с ускорением 1g (единичное усилие 1g эквивалентно гравитационному ускорению 9,8 м/с2), без сомнения, мяч ударится в стену X. Если мы измерим силу, которую мяч применяет к стене X, мы можем получить выходное значение 1g по оси X.

Рисунок 2 Внезапное движение
Рисунок 2 – Внезапное движение

Давайте посмотрим, что произойдет, если мы перенесем этот куб на Землю. Мяч просто упадет на стенку Z и применит силу 1g, как показано на рисунке ниже:

Рисунок 3 Сила тяжести
Рисунок 3 – Сила тяжести

В этом случае куб не перемещается, но мы всё равно получаем значение 1g по оси Z. Это потому, что сила тяжести тянет шар вниз с силой 1g.

Акселерометр измеряет статическое ускорение силы тяжести в приложениях, чувствительных к наклону, а также динамическое ускорение, возникающее в результате движения, удара или вибрации.

Как работает MEMS акселерометр?

Акселерометр MEMS (Micro Electro Mechanical Systems) состоит из микромеханической структуры, построенной поверх кремниевой пластины.

Рисунок 4 Внутренняя работа MEMS акселерометра ADXL335Внутренняя работа MEMS акселерометра ADXL335
Рисунок 4 – Внутренняя работа MEMS акселерометра ADXL335

Эта конструкция подвешена на поликремниевых пружинах. Это позволяет конструкции отклоняться, когда к определенной оси применяется ускорение.

Из-за прогиба емкость между неподвижными пластинами и пластинами, прикрепленными к подвешенной конструкции, изменяется. Это изменение емкости пропорционально ускорению по этой оси.

Датчик обрабатывает это изменение емкости и преобразует его в аналоговое выходное напряжение.

Обзор аппаратного обеспечения акселерометра ADXL335

Основой модуля является небольшой трехосный MEMS акселерометр с низким энергопотреблением и с чрезвычайно низким уровнем шума от Analog DevicesADXL335. Датчик имеет полный диапазон чувствительности ±3g. Он может измерять статическое ускорение, вызванное силой тяжести в приложениях, чувствительных к наклону, а также динамическое ускорение, вызванное движением, ударом или вибрацией.

Рисунок 5 Обзор аппаратного обеспечения модуля акселерометра ADXL335
Рисунок 5 – Обзор аппаратного обеспечения модуля акселерометра ADXL335

Датчик работает при питании от 1,8 до 3,6 В (оптимально 3,3 В) и обычно потребляет ток всего 350 мкА. Однако встроенный стабилизатор 3,3 В делает его идеальным выбором для взаимодействия с микроконтроллерами 5 В, такими как Arduino.

Эта дружественная макетная плата разводит каждый вывод ADXL335 на 6-выводный разъем с шагом 0,1 дюйма. Сюда входят 3 аналоговых выхода для измерений по осям X, Y и Z, 2 вывода питания и вывод самотестирования, который позволяет проверить работу датчика в конечном приложении.

Аналоговые выходы являются относительными, что означает, что выходной сигнал 0g номинально равен половине напряжения питания 3,3 В (1,65 В), -3g соответствует выходному напряжению 0 В, и 3g соответствует 3,3 В с полным масштабированием между ними.

Ниже приведена таблица с основными характеристиками микросхемы акселерометра ADXL335.

Характеристики микросхемы акселерометра ADXL335.
Рабочее напряжение1,8 В - 3,6 В
Рабочий ток350 мкА (типовой)
Диапазон чувствительности±3g (полная шкала)
Диапазон температурот -40° до + 85° C
Чувствительные оси3 оси
Чувствительностьот 270 до 330 мВ/g (относительно)
Ударопрочностьдо 10000g
Размер4мм х 4мм х 1,45 мм

Для более подробной информации обратитесь к техническому описанию по ссылке ниже.

Распиновка акселерометра ADXL335

Прежде чем погрузиться в подключения и примеры кода, давайте сначала взглянем на распиновку модуля акселерометра.

Рисунок 6 Распиновка модуля акселерометра ADXL335
Рисунок 6 – Распиновка модуля акселерометра ADXL335

Вывод VCC обеспечивает питание для акселерометра, который может быть подключен к 5 В на Arduino.

Вывод Выход X выводит аналоговое напряжение, пропорциональное ускорению, приложенному к оси X.

Вывод Выход Y выводит аналоговое напряжение, пропорциональное ускорению на оси Y.

Вывод Выход Z выводит аналоговое напряжение, пропорциональное ускорению на оси Z.

Вывод GND подключается к выводу GND на Arduino

Вывод ST (Self-Test) контролирует функцию самопроверки. Эта функция подробно обсуждается в конце.

Подключение акселерометра ADXL335 к Arduino UNO

Теперь, когда у нас есть полное представление о том, как работает акселерометр ADXL335, мы можем начать подключать его к нашей плате Arduino.

Подключение довольно простое. Начните с установки акселерометра на макетной плате. Подключите вывод VCC к выводу 5V на Arduino, а вывод GND – к выводу GND на Arduino. Также подключите выходы X, Y и Z к аналоговым выводам A0, A1 и A2 на Arduino.

Для получения точных результатов, нам нужно изменить опорное аналоговое напряжение (AREF) на Arduino. Это можно сделать, подключив вывод 3,3V на Arduino к выводу AREF.

Когда вы закончите, у вас должно получиться что-то похожее на показанное на рисунке ниже.

Рисунок 7 Подключение модуля акселерометра ADXL335 к Arduino UNO
Рисунок 7 – Подключение модуля акселерометра ADXL335 к Arduino UNO

Итак, теперь, когда мы подключили наш акселерометр, пришло время написать код и протестировать его.

Код Arduino – чтение показаний акселерометра ADXL335

Скетч довольно прост. Он просто отображает калиброванное выходное напряжение датчика для каждой оси через последовательный интерфейс. Протестируйте скетч, прежде чем мы начнем его подробный разбор.

const int xInput = A0;
const int yInput = A1;
const int zInput = A2;

// Инициализируем минимальное и максимальное необработанные значения для каждой оси
int RawMin = 0;
int RawMax = 1023;

// Берем несколько отсчетов, чтобы уменьшить шум
const int sampleSize = 10;

void setup() 
{
  analogReference(EXTERNAL);
  Serial.begin(9600);
}

void loop() 
{
  // Прочитать необработанные значения
  int xRaw = ReadAxis(xInput);
  int yRaw = ReadAxis(yInput);
  int zRaw = ReadAxis(zInput);

  // Преобразовать необработанные значения 'милли-g"
  long xScaled = map(xRaw, RawMin, RawMax, -3000, 3000);
  long yScaled = map(yRaw, RawMin, RawMax, -3000, 3000);
  long zScaled = map(zRaw, RawMin, RawMax, -3000, 3000);

  // Пересчитать в значения g с дробной частью
  float xAccel = xScaled / 1000.0;
  float yAccel = yScaled / 1000.0;
  float zAccel = zScaled / 1000.0;

  Serial.print("X, Y, Z  :: ");
  Serial.print(xRaw);
  Serial.print(", ");
  Serial.print(yRaw);
  Serial.print(", ");
  Serial.print(zRaw);
  Serial.print(" :: ");
  Serial.print(xAccel,0);
  Serial.print("G, ");
  Serial.print(yAccel,0);
  Serial.print("G, ");
  Serial.print(zAccel,0);
  Serial.println("G");

  delay(200);
}

// Взять отсчеты и вернуть среднее значение
int ReadAxis(int axisPin)
{
  long reading = 0;
  analogRead(axisPin);
  delay(1);
  for (int i = 0; i < sampleSize; i++)
  {
    reading += analogRead(axisPin);
  }
  return reading/sampleSize;
}

Скетч начинается с объявления аналоговых входных выводов Arduino, к которым подключены выходные выводы X, Y и Z датчика.

Далее мы определяем минимальные и максимальные значения, которые Arduino собирается предоставить. Поскольку плата Arduino содержит 10-разрядный аналого-цифровой преобразователь, она отобразит выходные напряжения датчика в диапазоне от 0 до 3,3 В в целочисленные значения в диапазоне от 0 до 1023. Именно поэтому для RawMin установлено значение 0, а для RawMax установлено значение 1023.

Переменная sampleSize указывает Arduino брать 10 отсчетов каждого преобразования, чтобы получить более точные результаты.

const int xInput = A0;
const int yInput = A1;
const int zInput = A2;

// Инициализируем минимальное и максимальное необработанные значения для каждой оси
int RawMin = 0;
int RawMax = 1023;

// Берем несколько отсчетов, чтобы уменьшить шум
const int sampleSize = 10;

В функции setup() мы должны установить аналоговое опорное напряжение на EXTERNAL, так как мы подключили 3,3 В к выводу AREF на Arduino. Это делается путем вызова analogReference(EXTERNAL).

Кроме этого, мы инициализируем здесь и последовательную связь с компьютером.

ПРЕДУПРЕЖДЕНИЕ

Если вы не вызовите analogReference(EXTERNAL), вы закоротите вместе активный источник опорного напряжения (внутренний) и вывод AREF, что, возможно, приведет к повреждению микроконтроллера на плате Arduino..

analogReference(EXTERNAL);
Serial.begin(9600);

В функции loop() мы считываем аналоговые выходы датчика каждые 200 мс. Вместо вызова функции analogRead() мы вызываем пользовательскую функцию ReadAxis(). Эта функция просто берет 10 выборок АЦП и возвращает среднее значение.

// Прочитать необработанные значения
int xRaw = ReadAxis(xInput);
int yRaw = ReadAxis(yInput);
int zRaw = ReadAxis(zInput);

Преобразование показаний ADXL335 в ускорение (g)

Следующий фрагмент кода является наиболее важной частью программы. Он преобразует аналоговые выходные напряжения датчика в ускорение свободного падения (g).

Встроенная в IDE функция map() выполняет фактическое преобразование. Таким образом, когда мы вызываем map(xRaw, RawMin, RawMax, -3000, 3000), значение RawMin будет преобразовываться в -3000, значение RawMax – в 3000, а значения между ними – в промежуточные значения.

Значения -3000 и 3000 не являются произвольными. Они фактически представляют ускорение свободного падения (в милли-g, которое составляет 1/1000 g), измеренное датчиком, то есть ± 3g (от -3000 до 3000 милли-g).

Например,

  • Когда датчик выдает 0 вольт на оси x, то есть xRaw = 0, функция map() возвращает -3000, представляющие -3g.
  • Когда датчик выдает 3,3 вольта по оси x, то есть xRaw = 1023, функция map() вернет 3000, представляющие +3g.
  • Когда датчик выдает 1,65 В на оси x, т.е. xRaw = 511, функция map() вернет 0, представляющий 0g.

Термин относительный будет иметь больше смысла, когда выходное напряжение будет увеличиваться линейно с ростом ускорения в заданном диапазоне.

// Преобразовать необработанные значения 'милли-g"
long xScaled = map(xRaw, RawMin, RawMax, -3000, 3000);
long yScaled = map(yRaw, RawMin, RawMax, -3000, 3000);
long zScaled = map(zRaw, RawMin, RawMax, -3000, 3000);

Наконец, выходной сигнал датчика уменьшается до дробного значения g с помощью деления на 1000 и выводится в монитор последовательного порта.

// Пересчитать в значения g с дробной частью
float xAccel = xScaled / 1000.0;
float yAccel = yScaled / 1000.0;
float zAccel = zScaled / 1000.0;

Serial.print("X, Y, Z  :: ");
Serial.print(xRaw);
Serial.print(", ");
Serial.print(yRaw);
Serial.print(", ");
Serial.print(zRaw);
Serial.print(" :: ");
Serial.print(xAccel,0);
Serial.print("G, ");
Serial.print(yAccel,0);
Serial.print("G, ");
Serial.print(zAccel,0);
Serial.println("G");

На следующих рисунках показан вывод данных акселерометра в монитор последовательного порта в разных положениях.

Рисунок 8 Вывод акселерометра ADXL335 на оси X -
Рисунок 8 – Вывод акселерометра ADXL335 на оси X -
Рисунок 9 Вывод акселерометра ADXL335 на оси Y +
Рисунок 9 – Вывод акселерометра ADXL335 на оси Y +
Рисунок 10 Вывод акселерометра ADXL335 на X +
Рисунок 10 – Вывод акселерометра ADXL335 на X +
Рисунок 11 Вывод акселерометра ADXL335 на оси Y -
Рисунок 11 – Вывод акселерометра ADXL335 на оси Y -
Рисунок 12 Вывод акселерометра ADXL335 на оси Z +
Рисунок 12 – Вывод акселерометра ADXL335 на оси Z +
Рисунок 13 Вывод акселерометра ADXL335 на оси Z -
Рисунок 13 – Вывод акселерометра ADXL335 на оси Z -

Функция самотестирования ADXL335

Акселерометр ADXL335 имеет функцию самопроверки, которая позволяет проверить работу датчика в конечном приложении.

Рисунок 14 Вывод ST (самопроверка) на модуле управляет этой функцией.
Рисунок 14 – Вывод ST (самопроверка) на модуле управляет этой функцией

Когда контакт ST подключен к 3,3 В, на пластину акселерометра внутри действует электростатическая сила. Результирующее движение пластины позволяет пользователю проверить работоспособность акселерометра.

Типичное изменение выходного сигнала:

  • -1,08 g (-325 мВ) по оси X
  • +1.08 g (+325 мВ) по оси Y
  • +1,83 g (+550 мВ) по оси Z

Этот вывод ST при нормальном использовании может быть подключен к земле или оставлен «висеть» в воздухе.

ПРЕДУПРЕЖДЕНИЕ

Подача на вывод ST напряжения выше 3,6 В может привести к повреждению акселерометра.

Теги

ArduinoАкселерометрДатчикИзмерениеМакетная платаПрограммированиеУскорение

На сайте работает сервис комментирования DISQUS, который позволяет вам оставлять комментарии на множестве сайтов, имея лишь один аккаунт на Disqus.com.

В случае комментирования в качестве гостя (без регистрации на disqus.com) для публикации комментария требуется время на премодерацию.


  • 2020-08-18Николай

    вывод ST при нормальном использовании должен быть подключенным земле иначе акселерометр не работает