X9C103S цифровой потенциометр 10 кОм

X9C103S — потенциометр 10 кОм с цифровым управлением, в котором изменение сопротивления происходит благодаря массиву из 99 резисторов.

Серия X9C представлена потенциометрами на различное сопротивление:

• X9C102 – 1 кОм;
• X9C103 – 10 кОм;
• X9C503 – 50 кОм;
• X9C104 – 100 кОм.

Особенности работы:

Назначение выводов:

• выходы VH, RW, VL, выходы потенциометра, максимальное напряжение через потенциометр 10В, ток 8мА;
• вход U/D: UP/DOWN, в зависимости от состояния этого входа, ползунок резистора перемещается вверх или вниз;
• вход INC: INCREMENT, управление ползунком, когда на входе изменяется состояние с 1 на 0, ползунок потенциометра делает один шаг, принцип работы как у аппаратного прерывания;
• вход CS: DEVICE SELECT, выбор устройства, чтобы микросхема начала принимать команды, нужно подать логический 0

У микросхемы нет привычного интерфейса вроде I2C или SPI, управление происходит по трем проводам, своеобразным способом.

Микросхема может хранить в EEPROM установленное значение потенциометра, но сохранит или нет, зависит от состояния входа INC в момент перехода входа CS.

Таблица из технического описания поясняет процесс:

Выбор режима цифрового потенциометра X9C103S

\(\overline{\text{CS}}\)	\(\overline{\text{INC}}\)	\(\text{U/}\overline{\text{D}}\)	Режим
L		H	Ползунок вверх
L		L	Ползунок вниз
	H	X	Сохранить положение ползунка
H	X	X	Режим ожидания
	L	X	Не сохранять, вернуться в режим ожидания
	L	H	Ползунок вверх (не рекомендуется)
	L	L	Ползунок вниз (не рекомендуется)

Пример работы с Arduino

Модуль можно подключать на любые свободные выходы Arduino. Ниже приведен пример кода.

// выходы к которым подключен модуль
#define UD  2
#define INC 3
#define CS  4

// поднимает ползунок в верх на 1 шаг
void up()
{
  digitalWrite(UD, HIGH);             // на U/D подаем единицу
  digitalWrite(INC, HIGH);            // и на INC тоже
  digitalWrite(CS, LOW);              // включаем микросхему
  delayMicroseconds(1);               // ждем
  digitalWrite(INC, LOW);             // дергаем вход INC
  delayMicroseconds(1);
  digitalWrite(INC, HIGH);
  delayMicroseconds(1);
  //digitalWrite(INC, LOW);           // в этом случае положение ползунка записано не будет
  digitalWrite(CS, HIGH);             // выключаем микросхему и записываем положение в EEPROM 
}

// опускаем ползунок в верх на 1 шаг
void down()
{
  digitalWrite(UD, LOW);
  digitalWrite(INC, HIGH);
  digitalWrite(CS, LOW);
  delayMicroseconds(1);
  digitalWrite(INC, LOW);
  delayMicroseconds(1);
  digitalWrite(INC, HIGH);
  delayMicroseconds(1);

  digitalWrite(CS, HIGH);
}

void setup() 
{
  Serial.begin(9600);

  pinMode(INC, OUTPUT);
  pinMode(UD, OUTPUT);
  pinMode(CS, OUTPUT);
  digitalWrite(CS, HIGH);             // выключаем микросхему
}

void loop() 
{
  if (Serial.available())             // проверяем, пришло ли что в Serial
  {
    if (Serial.read() == '0')        // если пришел 0
    {
      down();                         // опускаем ползунок
      Serial.print("-1");
    }
    else                            // иначе поднимаем
    {
      up();
      Serial.print("+1");
    }
  }
}

В примере две функции up() и down(), при вызове их, на микросхему подается команда поднять или опустить ползунок.

Выходы VL, VW, VH модуля подключаются на место обычного потенциометра, это может быть управление контрастностью символьных LCD дисплеев 1602 или управление микросхемой линейного стабилизатора напряжения LM317.

Магазины и цены