Усилительный каскад с общим эмиттером

Добавлено 5 октября 2017 в 00:20

В начале этой главы мы увидели, как транзисторы, работая в режиме либо «насыщения», либо «отсечки», могут использоваться в качестве ключей. В последнем разделе мы увидели, как транзисторы ведут себя в своих «активных» режимах, между экстремальными режимами насыщения и отсечки. Поскольку транзисторы способны управлять током аналоговым (плавно изменяющимся) способом, они находят применение и в качестве усилителей для аналоговых сигналов.

Одна из наиболее простых для изучения схем транзисторного усилителя ранее показала коммутирующие способности транзистора (рисунок ниже).

NPN транзистор как простой ключ
NPN транзистор как простой ключ (на рисунке показаны направления движения потоков электронов)

Она называется схемой с общим эмиттером, потому что (игнорируя батарею источника питания) и у источника сигнала, и у нагрузки есть общая точка подключения к транзистору – эмиттера (как показано на рисунке ниже). И, как мы увидим в последующих разделах этой главы, это не единственный способ использования транзистора в качестве усилителя.

Каскад усилителя с общим эмиттером: у входного и выходного сигналов при подключении к транзистору есть общая точка – эмиттер
Каскад усилителя с общим эмиттером: у входного и выходного сигналов при подключении к транзистору есть общая точка – эмиттер

Ранее небольшой ток от солнечного элемента насыщал транзистор, зажигавший лампу. Теперь зная, что транзисторы способны «задавливать» ток коллектора в соответствии с величиной тока базы, подаваемого от источника входного сигнала, мы можем увидеть, что в этой схеме яркость лампы может контролироваться яркостью света, падающего на солнечный элемент. Когда на солнечный элемент попадает мало света, лампа будет светиться тускло. По мере того, как на солнечный элемент попадает больше света, яркость лампы будет возрастать.

Предположим, что нас заинтересовало использование солнечного элемента в качестве измерителя яркости света. Мы хотим измерить яркость падающего света с помощью солнечного элемента, используя его выходной ток для управления стрелкой индикатора. Для этого можно подключить индикатор к солнечному элементу напрямую (рисунок ниже). На самом деле простейшие измерители яркости в фотографии работают подобным же образом.

Свет большой яркости напрямую управляет индикатором
Свет большой яркости напрямую управляет индикатором

Хотя этот способ может работать и при измерении умеренной яркости света, при низкой яркости он работать уже не будет. Поскольку солнечный элемент должен обеспечивать потребности в энергии индикатора для движения стрелки, то эта система неизбежно будет ограничена по своей чувствительности. Предполагая, что нам необходимо измерять очень низкие яркости света, нужно найти другое решение.

Возможно, самым прямым решением этой проблемы является использование транзистора (рисунок ниже) для усиления тока солнечного элемента, чтобы можно было получить большее отклонение стрелки индикатора для более тусклого света.

Ток солнечного элемента при низкой яркости света должен быть усилен
Ток солнечного элемента при низкой яркости света должен быть усилен (на рисунке показаны направления движения потоков электронов)

Ток через индикатор в этой схеме будет в β раз больше тока через солнечный элемент. Для транзистора с β, равным 100, это дает существенное увеличение чувствительности измерений. Разумно отметить, что дополнительная мощность для перемещения стрелки индикатора исходит от батареи в правой части схемы, а не от самого солнечного элемента. Всё, что делает ток солнечного элемента, это управляет током батареи, чтобы обеспечить более высокие показания индикатора, чем мог бы обеспечить солнечный элемент без посторонней помощи.

Поскольку транзистор является устройством, регулирующим ток, и поскольку движение стрелки индикатора определяется током через катушку индикатора, показания измерителя должны зависеть только от тока солнечного элемента, а не от величины напряжения, обеспечиваемого аккумулятором. Это означает, что точность схемы не зависит от состояния аккумулятора, что является важной особенностью! Всё, что требуется от батареи, – это определенные минимальные выходные напряжения и ток, способные отклонить стрелку индикатора на всю шкалу.

Другим способом использования схемы с общим эмиттером является получение определяемого входным сигналом выходного напряжения, а не определенного значения выходного тока. Давайте заменим стрелочный индикатор на простой резистор и измерим напряжение между коллектором и эмиттером (рисунок ниже).

Благодаря току через резистор нагрузки усилитель с общем эмиттером выдает на выход напряжение
Благодаря току через резистор нагрузки усилитель с общем эмиттером выдает на выход напряжение

Когда солнечный элемент затемнен (нет тока), транзистор будет находиться в режиме отсечки, и будет вести себя как разомкнутый ключ между коллектором и эмиттером. Это приведет к максимальному падению напряжения между коллектором и эмиттером, что даст максимальное Vвых, равное полному напряжению батареи.

При полной мощности (максимальной освещенности) солнечный элемент будет приводить транзистор в режим насыщения, заставляя его вести себя как замкнутый ключ между коллектором и эмиттером. Результатом будет минимальное падение напряжение между коллектором и эмиттером, или почти нулевое выходное напряжение. На самом деле открытый транзистор никогда не сможет достичь нулевого падения напряжения между коллектором и эмиттером из-за двух PN-переходов, через которые должен проходить ток коллектора. Однако это «напряжение насыщения коллектор-эмиттер» будет довольно низким, примерно несколько десятых долей вольта, в зависимости от конкретного используемого транзистора.

При выходных сигналах солнечного элемента для уровней освещенности где-то между нулем и максимумом транзистор будет находиться в активном режиме, а выходное напряжение будет где-то между нулем и полным напряжением батареи. Важно отметить, что в схеме с общим эмиттером выходное напряжение инвертируется относительно входного сигнала. То есть по мере увеличения входного сигнала выходное напряжение уменьшается. По этой причине схема усилителя с общим эмиттером называется инвертирующим усилителем.

Быстрое моделирование схемы в SPICE (рисунок и список соединений ниже) проверит наши выводы об этой усилительной схеме.

Схема усилителя с общим эмиттером с номерами узлов в SPICE (список соединений приведен ниже)
Схема усилителя с общим эмиттером с номерами узлов в SPICE (список соединений приведен ниже)
*common-emitter amplifier 
i1 0 1 dc
q1 2 1 0 mod1
r 3 2 5000
v1 3 0 dc 15
.model mod1 npn
.dc i1 0 50u 2u
.plot dc v(2,0)
.end
Схема с общим эмиттером: зависимость выходного напряжения коллектора от входного тока базы
Схема с общим эмиттером: зависимость выходного напряжения коллектора от входного тока базы

В начале моделирования (на рисунке выше), когда источник ток (солнечного элемента) выдает нулевой ток, транзистор находится в режиме отсечки, и выходное напряжение усилителя (между узлами 2 и 0) равно всем 15 вольтам напряжения батареи. По мере того, как ток солнечного элемента начинает увеличиваться, выходное напряжение пропорционально уменьшается, пока транзистор не достигнет насыщения при токе базы 30 мкА (ток коллектора 3 мА). Обратите внимание, как график выходного напряжения идеально линеен (шаги по 1 вольту от 15 вольт до 1 вольта) до точки насыщения, где он никогда не достигнет нуля. Этот эффект упоминался ранее, полностью открытый транзистор не может достичь точно нулевого падения напряжения между коллектором и эмиттером из-за наличия внутренних переходов. То, что мы видим, это резкое снижение выходного напряжения от 1 вольта до 0.2261 вольта при возрастании входного тока с 28 мкА до 30 мкА, а затем дальнейшее снижение выходного напряжения (хотя и со значительно меньшим шагом). Наименьшее выходное напряжение, полученное при этом моделировании, составляет 0.1299 вольта, почти равно нулю.

До сих пор мы видели, как транзистор, как усилитель сигналов постоянных напряжения и тока. В примере измерения освещенности с помощью солнечного элемента нам было интересно усилить выходной сигнал постоянного тока от солнечного элемента для управления стрелочным индикатором постоянного тока или получить на выходе постоянное напряжение. Однако это не единственный способ использования транзистора в качестве усилителя. Часто бывает, необходим усилитель переменного тока для усиления сигналов переменных тока и напряжения. Один из наиболее распространенных случаев – аудио электроника (радио, телевидение). Ранее мы видели пример аудио сигнала от камертона, активирующего транзисторный ключ (рисунок ниже). Посмотрим, можем ли мы изменить эту схему для передачи мощности не на лампу, а на динамик.

Транзисторный ключ, активируемый звуком (на рисунке показны направления движения потоков электронов)
Транзисторный ключ, активируемый звуком (на рисунке показаны направления движения потоков электронов)

В исходной схеме двухполупериодный мостовой выпрямитель использовался для преобразования сигнала переменного напряжения от микрофона в постоянное напряжение для управления входом транзистора. Всё, что нам было нужно, это включить лампу с помощью звукового сигнала от микрофона, для этих целей такой схемы было достаточно. Но теперь мы хотим усилить сигнал переменного напряжения и подать его на динамик. Это означает, что мы больше не можем выпрямлять сигнал с выхода микрофона, поскольку для подачи на транзистор нам нужен неискаженный сигнал! Удалим из схемы мостовой выпрямитель и заменим лампу на динамик.

Усилитель с общим эмиттером подает на динамик сигнал звуковой частоты
Усилитель с общим эмиттером подает на динамик сигнал звуковой частоты

Так как микрофон может генерировать напряжения, превышающие прямое падение напряжения на PN-переходе база-эмиттер, последовательно с микрофоном я поместил резистор. Давайте промоделируем схему на рисунке ниже с помощью SPICE. Список соединений приведен ниже.

SPICE модель аудиоусилителя с общим эмиттером
SPICE модель аудио усилителя с общим эмиттером
common-emitter amplifier 
vinput 1 0 sin (0 1.5 2000 0 0)
r1 1 2 1k
q1 3 2 0 mod1
rspkr 3 4 8 
v1 4 0 dc 15
.model mod1 npn
.tran 0.02m 0.74m
.plot tran v(1,0) i(v1)
.end
На коллекторе сигнал обрезается из-за отсутствия на базе смещения постоянным напряжением
На коллекторе сигнал обрезается из-за отсутствия на базе смещения постоянным напряжением

На графиках моделирования (рисунок выше) показаны как входное напряжение (сигнал переменного напряжения с амплитудой 1,5 вольта и частотой 2000 Гц), так и ток через батарею 15 вольт, который совпадает с током через динамик. Здесь мы видим полную синусоиду входного переменного напряжения (и с положительной, и с отрицательной полуволнами) и полуволны выходного тока только одной полярности. Если бы мы на самом деле подали этот сигнал на динамик, звук из него был бы сильно искажен.

Что не так с этой схемой? Почему она не будет точно воспроизводить полную форму переменного напряжения от микрофона? Ответ на этот вопрос можно найти путем тщательной проверки модели транзистора на основе диода и источника тока (рисунок ниже).

Модель показывает, что ток базы протекает только в одном направлении
Модель показывает, что ток базы протекает только в одном направлении

Ток коллектора контролируется, или регулируется, в режиме стабилизации тока на постоянном значении в соответствии с величиной тока, протекающего через переход база-эмиттер. Обратите внимание, что оба пути протекания тока через транзистор являются однонаправленными: только одно направление! Несмотря на наше намерение использовать транзистор для усиления сигнала переменного тока, он, по сути, является устройством постоянного тока, которое способно работать с токами только одного направления. Мы можем подать входной сигнал переменного напряжения между базой и эмиттером, но электроны в этой схеме не смогут протекать во время того полупериода, когда переход база-эмиттер будет смещен в обратном направлении. Следовательно, транзистор будет оставаться в режиме отсечки на протяжении всей этой части периода. Он будет «включаться» в активный режим только в том случае, если входное напряжение имеет правильную полярность, чтобы смещать переход база-эмиттер в прямом направлении, и только тогда, когда это напряжение достаточно велико, чтобы превысить прямое падение напряжения перехода. Помните, что биполярные транзисторы являются устройствами, которые управляются током: они регулируют ток коллектора, основываясь на протекании тока от базы к эмиттеру, а не на наличии напряжения между базой и эмиттером.

Единственный способ, с помощью которого мы можем заставить транзистор выдавать в динамик сигнала без искажения его формы, заключается в том, чтобы удерживать транзистор в активном режиме всё время. Это значит, что мы должны поддерживать ток через базу в течение всего периода входного сигнала. Следовательно, PN-переход база-эмиттер должен постоянно быть смещен в прямом направлении. К счастью, это может быть достигнуто с помощью постоянного напряжения смещения, добавленного к входному сигналу. При подключении источника постоянного напряжения с достаточно большим уровнем последовательно с источником сигнала переменного напряжения прямое смещение может поддерживаться во всех точках синусоиды сигнала (рисунок ниже).

Vсмещ удерживает транзистор в активном режиме
Vсмещ удерживает транзистор в активном режиме
common-emitter amplifier 
vinput 1 5 sin (0 1.5 2000 0 0)
vbias 5 0 dc 2.3
r1 1 2 1k
q1 3 2 0 mod1
rspkr 3 4 8
v1 4 0 dc 15
.model mod1 npn
.tran 0.02m 0.78m
.plot tran v(1,0) i(v1)
.end
Благодаря Vсмещ выходной ток I(v(1)) не искажается
Благодаря Vсмещ выходной ток I(v(1)) не искажается

При наличии источника напряжения смещения 2,3 вольта транзистор остается в активном режиме на протяжении всего периода синусоиды, верно воспроизводя форму сигнала на динамике (рисунок выше). Обратите внимание, что входное напряжение (измеренное между узлами 1 и 0) колеблется между примерно 0,8 вольта и 3,8 вольта, как и ожидалось, размах составляет 3 вольта (амплитуда напряжения источника равна 1,5 вольта). Выходной ток (протекает через динамик) изменяется от нуля до почти 300 мА и на 180° отличается по фазе от входного сигнала (с микрофона).

На рисунке ниже показан другой вид этой же схемы, на этот раз с несколькими осциллографами, подключенными к интересующим нас точкам для отображения соответствующих сигналов.

Вход базы смещен вверх. Выход проинвертирован.
Вход базы смещен вверх. Выход инвертирован.

Важной частью является необходимость смещения в схеме транзисторного усилителя для получения полного воспроизведения формы сигнала. Отдельный раздел этой главы будет полностью посвящен объектам и способам смещения. На данный момент достаточно понять, что смещение может потребоваться для получения на выходе усилителя напряжения и тока правильной формы.

Теперь, когда у нас есть работающая схема усилителя, мы можем исследовать ее напряжение, ток и усиление. Типовой транзистор, используемый в этих исследованиях, имеет значение β = 100, о чем свидетельствует короткая распечатка параметров транзистора, приведенная ниже (этот список параметров для краткости был сокращен).

SPICE параметры биполярного транзистора:

type        npn   
is        1.00E-16
bf         100.000
nf           1.000
br           1.000
nr           1.000

β указан под аббревиатурой "bf", что фактически означает "бета, прямое" ( “beta, forward”). Если бы мы захотели вставить для исследования наш собственный коэффициент β, мы могли бы сделать это в строке .model в списке соединений SPICE.

Так как β – это отношение тока коллектора к току базы, и у нас нагрузка соединена последовательно с коллектором транзистора, а наш источник соединен последовательно с базой, отношение выходного тока к входному току будет равно бета. Таким образом, усиление по току в этом примере усилителя составляет 100.

Усиление по напряжению посчитать немного сложнее, чем усиление по току. Как всегда, коэффициент усиления по напряжению определяется как отношение выходного напряжения к входному напряжению. Чтобы экспериментально определить его, мы изменим наш последний анализ SPICE для построения графика не выходного тока, а выходного напряжения, чтобы сравнить два графика напряжения (рисунок ниже).

common-emitter amplifier
vinput 1 5 sin (0 1.5 2000 0 0)
vbias 5 0 dc 2.3
r1 1 2 1k
q1 3 2 0 mod1
rspkr 3 4 8
v1 4 0 dc 15
.model mod1 npn
.tran 0.02m 0.78m
.plot tran v(1,0) v(3)
.end
Выходное напряжение V(1) на сопротивлении rдинамик для сравнения со входным сигналом
Выходное напряжение V(1) на сопротивлении rдинамик для сравнения со входным сигналом

При построении в одном масштабе (от 0 до 4 вольт) мы видим, что выходной сигнал на рисунке выше имеет меньшую амплитуду, чем входной сигнал, и к тому же он находится на более высоком уровне смещения по сравнению с входным сигналом. Поскольку коэффициент усиления по напряжению для усилителя переменного тока определяется отношением амплитуд, мы можем игнорировать любую разницу в смещениях по постоянному напряжению между этими двумя сигналами. Несмотря на это, входной сигнал всё равно больше выходного, что говорит о том, что коэффициент усиления по напряжению меньше 1 (отрицательное значение в дБ).

Честно говоря, этот низкий коэффициент усиления по напряжению не характерен для всех усилителей с общим эмиттером. Это является следствием большого несоответствия между входным сопротивлением и сопротивлением нагрузки. Наше входное сопротивление (R1) здесь составляет 1000 Ом, а нагрузка (динамик) составляет только 8 Ом. Поскольку коэффициент усиления по току определяется исключительно β, и поскольку этот параметр β фиксирован, коэффициент усиления по току для этого усилителя не изменится с изменением любого из этих сопротивлений. Однако коэффициент усиления по напряжению зависит от этих сопротивлений. Если мы изменим сопротивление нагрузки, сделав его более большим, падение напряжения на нем пропорционально увеличится при тех же значениях токов, и мы увидим на графике сигнал с большей амплитудой. Давайте попробуем промоделировать схему снова, но на этот раз с нагрузкой 30 Ом (рисунок ниже).

common-emitter amplifier
vinput 1 5 sin (0 1.5 2000 0 0)
vbias 5 0 dc 2.3
r1 1 2 1k
q1 3 2 0 mod1
rspkr 3 4 30
v1 4 0 dc 15
.model mod1 npn
.tran 0.02m 0.78m
.plot tran v(1,0) v(3)
.end
Увеличение rдинамик до 30 Ом увеличивает выходное напряжение
Увеличение rдинамик до 30 Ом увеличивает выходное напряжение

На этот раз размах выходного напряжения значительно больше, чем у входного напряжения (рисунок выше). При внимательном рассмотрении мы видим, что размах выходного сигнала составляет примерно 9 вольт, примерно в 3 раза больше размаха входного сигнала.

Мы можем выполнить еще одни компьютерный анализ этой схемы, на этот раз поручая SPICE с точки зрения переменного напряжения, давая нам значения амплитуд входных и выходных напряжений, вместо осциллограмм (таблица ниже).

Список соединений SPICE для печати входных и выходных значений переменных напряжений.

common-emitter amplifier
vinput 1 5 ac 1.5
vbias 5 0 dc 2.3
r1 1 2 1k
q1 3 2 0 mod1   
rspkr 3 4 30    
v1 4 0 dc 15    
.model mod1 npn 
.ac lin 1 2000 2000     
.print ac v(1,0) v(4,3) 
.end    

freq          v(1)        v(4,3)      
2.000E+03     1.500E+00   4.418E+00

Измерения амплитуд сигналов на входе и на выходе показали 1,5 вольта на входе и 4,418 вольта на выходе. Это дает нам коэффициент усиления по напряжению 2,9453 (4,418 В / 1,5 В), или 9,3827 дБ.

\[A_V = { V_{вых} \over V_{вх}}\]

\[A_V = { 4,418 В \over 1,5 В}\]

\[A_V = 2,9453\]

\[A_{V(дБ)} = 20 \log A_{V(единицы)}\]

\[A_{V(дБ)} = 20 \log 2,9453\]

\[A_{V(дБ)} = 9,3827 дБ\]

Поскольку коэффициент усиления по току для усилительного каскада с общим эмиттером фиксирован и равен β, а входное и выходное напряжения будут равных входному и выходному токам, умноженным на соответствующие сопротивления, мы можем получить формулу для приближенного определения коэффициента усиления по напряжению:

\[A_V = \beta { R_{вых} \over R_{вх} }\]

\[A_V = (100) { 30 Ом \over 1000 Ом }\]

\[A_V = 3\]

\[A_{V(дБ)} = 20 \log A_{V(единицы)}\]

\[A_{V(дБ)} = 20 \log 3\]

\[A_{V(дБ)} = 9,5424 дБ\]

Как вы можете видеть, расчетный коэффициент усиления по напряжению довольно близок к результатам моделирования. При идеально линейном поведении транзисторов эти два набора значений будут точно равны. SPICE делает умную работу по учету многих «причуд» работы биполярного транзистора при их анализе, следовательно, присутствует и небольшое несоответствие между расчетными значениями и результатами моделирования.

Эти коэффициенты усиления по напряжению остаются неизменными независимо от того, где в схеме мы измеряем выходное напряжение: между коллектором и эмиттером или на резисторе нагрузки, как это было сделано при последнем анализе. Изменение значения выходного напряжения для любого заданного значения входного напряжения будет оставаться неизменным. В качестве доказательства этого утверждения рассмотрите два следующих анализа SPICE. Первое моделирование на рисунке ниже проведено во временной области, чтобы получить графики входного и выходного напряжений. Вы заметите, что эти два сигнала отличаются по фазе на 180°. Второе моделирование в таблице ниже представляет собой анализ по переменному напряжению, предоставляющий просто показания пиковых напряжений для входа и для выхода.

Список соединений SPICE для первого анализа:

common-emitter amplifier
vinput 1 5 sin (0 1.5 2000 0 0)
vbias 5 0 dc 2.3
r1 1 2 1k
q1 3 2 0 mod1
rspkr 3 4 30
v1 4 0 dc 15
.model mod1 npn
.tran 0.02m 0.74m
.plot tran v(1,0) v(3,0)
.end
Усилительный каскад с общим эмиттером с Rдинамик усиливает сигнал по напряжению
Усилительный каскад с общим эмиттером с Rдинамик усиливает сигнал по напряжению

Список соединений SPICE для анализа по переменному току:

common-emitter amplifier
vinput 1 5 ac 1.5       
vbias 5 0 dc 2.3
r1 1 2 1k       
q1 3 2 0 mod1   
rspkr 3 4 30    
v1 4 0 dc 15    
.model mod1 npn 
.ac lin 1 2000 2000     
.print ac v(1,0) v(3,0) 
.end    

freq          v(1)        v(3)
2.000E+03     1.500E+00   4.418E+00

У нас всё еще пиковое напряжение на выходе равно 4,418 вольт при пиковом напряжении на входе 1,5 вольта. Единственное отличие от данных последнего моделирования – это то, что в первом моделировании нам видна фаза выходного напряжения.

До сих пор в примерах схем, показанных в этом разделе, мы использовали только NPN транзисторы. PNP транзисторы также можно использовать в любом типе схемы усилительного каскада, если соблюдается правильность полярностей и направлений токов, и схема с общим эмиттером не является исключением. Инверсия и усиление выходного сигнала у усилителя на PNP транзисторе, аналогичны усилителю на NPN транзисторе, только полярности батарей будут противоположными (рисунок ниже).

PNP версия усилительного каскада с общим эмиттером
PNP версия усилительного каскада с общим эмиттером

Подведем итоги:

  • Усилительные транзисторные каскады с общим эмиттером носят такое название, потому что у входного и выходного напряжений есть общая точка подключения к транзистору - эмиттер (не учитывая каких-либо источников питания).
  • Транзисторы – это, по сути, устройства постоянного тока: они не могут напрямую обрабатывать напряжения или токи, которые меняют своё направление. Чтобы заставить их работать для усиления сигналов переменного напряжения, входной сигнал должен быть смещен постоянным напряжением, чтобы удерживать транзистор в активном режиме на протяжении всего периода синусоиды сигнала. Это называется смещением.
  • Если выходное напряжение в схеме усилителя с общим эмиттером измеряется между эмиттером и коллектором, оно будет на 180° отличаться по фазе от входного напряжения. Таким образом, усилитель с общим эмиттером называется схемой инвертирующего усилителя.
  • Коэффициент усиления по току транзисторного усилителя с общим эмиттером с нагрузкой, подключенной последовательно с коллектором, равен β. Коэффициент усиления по напряжению транзисторного усилителя с общим эмиттером может быть приблизительно рассчитан по формуле:
    \[A_V = \beta { R_{вых} \over R_{вх} }\]
    где Rвых – это резистор, соединенный последовательно с коллектором; а Rвх – это резистор, соединенный последовательно с базой.

Теги

LTspiceSPICEБиполярный транзисторКаскад с общим эмиттеромКоэффициент усиления по напряжениюКоэффициент усиления по токуМоделированиеОбучениеСмещение транзистораЭлектроника

На сайте работает сервис комментирования DISQUS, который позволяет вам оставлять комментарии на множестве сайтов, имея лишь один аккаунт на Disqus.com.

В случае комментирования в качестве гостя (без регистрации на disqus.com) для публикации комментария требуется время на премодерацию.