Усилительный каскад с общей базой

Добавлено 6 октября 2017 в 12:14

Глава 4 – Биполярные транзисторы

Последний тип схемы усилителя на биполярном транзисторе (рисунок ниже), который мы должны изучить, это схема с общей базой. Эта конфигурация сложнее двух предыдущих и менее распространена из-за своих странных рабочих характеристик.

Усилитель с общей базой
Усилитель с общей базой (стрелками показаны направления движения потоков электронов)

Она называется схемой с общей базой, поскольку (игнорируя источники питания постоянного напряжения) источник сигнала и нагрузка делят между собой вывод базы как общую точку (рисунок ниже).

Усилитель с общей базой: вход между эмиттером и базой, выход между коллектором и базой
Усилитель с общей базой: вход между эмиттером и базой, выход между коллектором и базой

Возможно, наиболее яркой характеристикой этого типа включения транзистора является то, что источник входного сигнала обеспечивать полный ток эмиттера транзистора, о чём свидетельствуют толстые стрелки на первой иллюстрации. Как известно, ток эмиттера больше, чем любой другой ток в транзисторе, так как является суммой токов базы и коллектора. В последних двух типах усилительных каскадов источник сигнала был подключен к выводу базы транзистора, таким образом, работая на минимально возможном токе.

Поскольку в этой схеме входной ток превышает все другие токи, включая выходной ток, коэффициент усиления по току на самом деле меньше 1 (обратите внимание, как Rнагр подключен к коллектору, тем самым пропуская через себя немного меньший ток, чем источник сигнала). Другими словами, эта схема ослабляет ток, а не усиливает его. В схемах с общим эмиттером и общим коллектором из всех параметров транзистора с усилением тесно был связан β. В схеме с общей базой нам нужен другой основной параметр транзистора: отношение тока коллектора к току эмиттера, который представляет собой дробное число, всегда меньше 1. Это дробное значение для любого транзистора называется коэффициентом α (альфа).

Поскольку данная схема, очевидно, не может повысить ток сигнала, было бы разумным ожидать, что она увеличит напряжение сигнала. Моделирование SPICE схемы на рисунке ниже подтвердит это предположение.

Схема с общей базой для SPICE анализа по постоянному току
Схема с общей базой для SPICE анализа по постоянному току
common-base amplifier
vin 0 1
r1 1 2 100
q1 4 0 2 mod1
v1 3 0 dc 15
rload 3 4 5k
.model mod1 npn
.dc vin 0.6 1.2 .02
.plot dc v(3,4)
.end
Усилитель с общей базой: график зависимости выходного напряжения от входного напряжения
Усилитель с общей базой: график зависимости выходного напряжения от входного напряжения

Обратите внимание, что выходное напряжение изменяется практически от нуля (отсечка) до 15,75 вольт (насыщение), при этом входное напряжение меняется от 0,6 вольта до 1,2 вольта. Фактически, график выходного напряжения не показывает роста примерно до 0,7 вольта на входе и прекращает расти (выпрямляется) примерно при 1,12 вольта на входе. Это показывает довольно большой коэффициент усиления по напряжению с интервалом выходных напряжений 15,75 вольт и интервалом входных напряжений всего 0,42 вольт: коэффициент усиления составляет 37,5 раз, или 31,48 дБ. Также обратите внимание на то, как при насыщении выходное напряжение (измеренное на Rнагр) на самом деле превышает напряжение источника питания (15 вольт) из-за эффекта последовательного добавления источника входного напряжения.

Второй SPICE анализ модифицированной схемы (рисунок ниже) с источником сигнала переменного напряжения (и постоянным напряжением смещения) говорит о том же: о высоком коэффициенте усиления по напряжению.

Схема с общей базой для SPICE анализа по переменному току
Схема с общей базой для SPICE анализа по переменному току
common-base amplifier
vin 5 2 sin (0 0.12 2000 0 0)
vbias 0 1  dc 0.95
r1 2 1 100
q1 4 0 5 mod1
v1 3 0 dc 15
rload 3 4 5k
.model mod1 npn
.tran 0.02m 0.78m
.plot tran v(5,2) v(4)
.end

Как вы можете видеть, входной и выходной сигналы на рисунке ниже синфазны друг с другом. Это говорит о том, что усилитель с общей базой является неинвертирующим.

Усилительный каскад с общей базой: осциллограммы входного и выходного напряжений
Усилительный каскад с общей базой: осциллограммы входного и выходного напряжений

SPICE анализ по переменному току в таблице ниже на одной частоте 2 кГц предоставляет данные о входном и выходном напряжениях для расчета коэффициента усиления.

AC анализ схемы с общей базой на частоте 2 кГц: список соединений и выходные данные

common-base amplifier
vin 5 2  ac 0.1 sin
vbias 0 1  dc 0.95
r1 2 1 100
q1 4 0 5 mod1
v1 3 0 dc 15    
rload 3 4 5k    
.model mod1 npn 
.ac dec 1 2000 2000
.print ac vm(5,2) vm(4,3) 
.end

frequency       mag(v(5,2))     mag(v(4,3))
--------------------------------------------
0.000000e+00    1.000000e-01    4.273864e+00

Значения напряжений из второго анализа (таблица выше) показывают коэффициент усиления по напряжению 42,74 (4,274 В / 0.1 В), или 32,617 дБ:

\[A_V = { V_{вых} \over V_{вх} }\]

\[A_V = { 4,274 В \over 0,10 В }\]

\[A_V = 42,74\]

\[A_{V(дБ)} = 20 \log A_{V(раз)}\]

\[A_{V(дБ)} = 20 \log 42,74\]

\[A_{V(дБ)} = 32,62 дБ\]

Вот еще один вид схемы с общей базой (рисунок ниже), на которой видны фазы и смещения по постоянному напряжению для разны сигналов в только что промоделированной схеме.

Соотношения фаз и смещений в усилителе на NPN транзисторе с общей базой
Соотношения фаз и смещений в усилителе на NPN транзисторе с общей базой

То же самое для PNP транзистора (рисунок ниже).

Соотношения фаз и смещений в усилителе на PNP транзисторе с общей базой
Соотношения фаз и смещений в усилителе на PNP транзисторе с общей базой

Для схемы усилителя с общей базой определить заранее коэффициент усиления по напряжению довольно сложно, что связано с аппроксимацией поведения транзистора, которое трудно измерить напрямую. В отличие от других типов усилительных схема, где коэффициент усиления по напряжению либо устанавливается соотношением двух резисторов (в схеме с общим эмиттером), либо фиксировался на неизменном значении (схема с общим коллектором), коэффициент усиления по напряжению в схеме с общей базой зависит во многом от величины напряжения смещения входного сигнала. Как выясняется, внутреннее сопротивление транзистора между эмиттером и базой играет важную роль в определении коэффициента усиления по напряжению, и это сопротивление изменяется в зависимости от величины тока, протекающего через эмиттер.

Хотя это явление трудно объяснить, его довольно легко продемонстрировать с помощью компьютерного моделирования. Я собираюсь запустить несколько SPICE моделирований схемы усилителя с общей базой (предыдущий рисунок), слегка изменив постоянное напряжение смещения (vbias в коде ниже), оставив теми же амплитуду входного сигнала переменного напряжения и все остальные параметры схемы. Когда в разных моделированиях коэффициент усиления по напряжению будет меняться, это будет заметно по разным амплитудам выходного напряжения.

Несмотря на то, что эти анализы будут проводиться в режиме “transfer function” (коэффициент передачи), каждый из них был сначала проверен в режиме временного анализа (построен график напряжения в зависимости от времени), чтобы гарантировать, что вся синусоида сигнала была воспроизведена точно, а не «обрезана» из-за неправильного смещения. Смотрите "*.tran 0.02m 0.78m" в коде ниже, это «закомментирование» оператора временного анализа. Вычисление коэффициента усиления не может основываться на сигналах искаженной формы. SPICE может для нас рассчитать коэффициент усиления небольшого сигнала постоянного напряжения с помощью оператора "*.tf v(4) vin". Выходное напряжение – это v(4), а входное напряжение – это vin.

common-base amp vbias=0.85V
vin 5 2  sin (0 0.12 2000 0 0)
vbias 0 1  dc 0.85
r1 2 1 100      
q1 4 0 5 mod1   
v1 3 0 dc 15    
rload 3 4 5k    
.model mod1 npn 
*.tran 0.02m 0.78m
.tf v(4) vin
.end
common-base amp current gain
Iin 55 5 0A
vin 55 2  sin (0 0.12 2000 0 0)
vbias 0 1  dc 0.8753
r1 2 1 100      
q1 4 0 5 mod1   
v1 3 0 dc 15    
rload 3 4 5k    
.model mod1 npn 
*.tran 0.02m 0.78m
.tf I(v1) Iin
.end
Transfer function information:
transfer function = 9.900990e-01
iin input impedance = 9.900923e+11
v1 output impedance = 1.000000e+20
Список соединений SPICE (слева): Схема усилителя с общей базой, функция передачи (коэффициент усиления по напряжению) для различных постоянных напряжений смещения. Обратите внимание на оператор .tf v(4) vin.
Список соединений SPICE (справа): Схема усилителя с общей базой, коэффициент усиления по току; функция передачи для коэффициента усиления по постоянному току равна I(v1)/Iin. Обратите внимание на оператор .tf I(v1) Iin

Командная строка spice -b filename.cir благодаря оператору .tf выводит следующие данные: transfer_function (коэффициент передачи), output_impedance (выходное сопротивление) и input_impedance (входное сопротивление). Сокращенный вывод команды, запущенной для напряжений смещения vbias0.85, 0.90, 0.95, 1.00 вольт, приведен ниже

Вывод SPICE: коэффициент передачи схемы с общей базой:

Circuit: common-base amp vbias=0.85V        // напряжение смещения 0,85 вольта
transfer_function = 3.756565e+01            // коэффициент передачи
output_impedance_at_v(4) = 5.000000e+03     // выходное сопротивление
vin#input_impedance = 1.317825e+02          // входное сопротивление
 
Circuit: common-base amp vbias=0.8753V Ic=1 mA  // напряжение смещения 0,8753 вольта
Transfer function information:
transfer_function = 3.942567e+01            // коэффициент передачи
output_impedance_at_v(4) = 5.000000e+03     // выходное сопротивление
vin#input_impedance = 1.255653e+02          // входное сопротивление
 
Circuit: common-base amp vbias=0.9V         // напряжение смещения 0,9 вольта
transfer_function = 4.079542e+01            // коэффициент передачи
output_impedance_at_v(4) = 5.000000e+03     // выходное сопротивление
vin#input_impedance = 1.213493e+02          // входное сопротивление
 
Circuit: common-base amp vbias=0.95V        // напряжение смещения 0,95 вольта
transfer_function = 4.273864e+01            // коэффициент передачи
output_impedance_at_v(4) = 5.000000e+03     // выходное сопротивление
vin#input_impedance = 1.158318e+02          // входное сопротивление
 
Circuit: common-base amp vbias=1.00V        // напряжение смещения 1,00 вольт
transfer_function = 4.401137e+01            // коэффициент передачи
output_impedance_at_v(4) = 5.000000e+03     // выходное сопротивление
vin#input_impedance = 1.124822e+02          // входное сопротивление

Тенденция в списке выше должна быть очевидна. С увеличением постоянного напряжения смещения также увеличивается и коэффициент усиления по напряжению (transfer_function). Мы видим, что коэффициент усиления по напряжению увеличивается, потому что каждео последующее моделирование (vbias = 0.85, 0.8753, 0.90, 0.95, 1.00 В) дает больший коэффициент усиления (transfer_function = 37.6, 39.4 40.8, 42.7, 44.0) соответственно. Эти изменения во многом обусловлены незначительными изменениями напряжения смещения.

Последние три строки в списке соединений выше (справа) показывают коэффициент усиления по току I(v1)/Iin = 0,99 (последние две строки выглядят неправильными). Это имеет смысл для β=100; α= β/(β+1), α=0.99=100/(100-1). Это сочетание низкого коэффициента усиления по току (всегда меньше 1) и несколько непредсказуемого коэффициента усиления по напряжению говорит не в пользу схемы с общей базой, оставляя ей лишь несколько вариантов практических применений.

Эти несколько приложений включают в себя радиочастотные усилители. База, посаженная на корпус, помогает защитить входной сигнал на эмиттере от входного сигнала на коллекторе, предотвращая нестабильность в радиочастотных усилителях. Схема с общей базой может использоваться на более высоких частотах, чем схемы с общим эмиттером и общим коллектором. Смотрите раздел «Радиочастотный усилитель мощности 750 мВт класса C с общей базой» в главе 9. Более сложную схему можно увидеть в разделе «Усилитель малых сигналов класса A с общей базой и высоким коэффициентом усиления» в главе 9.

Подведем итоги:

  • Транзисторные усилители с общей базой называются так, потому что точки подачи входного напряжения и снятия выходного напряжения совместно используют вывод базы транзистора (игнорируя все источники питания).
  • Коэффициент усиления по току усилителя с общей базой всегда меньше 1. Коэффициент усиления по напряжению зависит от входных и выходных сопротивлений, а также от внутреннего сопротивления перехода эмиттер-база, которое может измениться при изменении постоянного напряжения смещения. Достаточно сказать, коэффициент усиления по напряжению у усилителя с общей базой может быть очень высоким.
  • Отношение тока коллектора транзистора к току эмиттера называется коэффициентом α. Значение α для любого транзистора всегда меньше единицы.

На сайте работает сервис комментирования DISQUS, который позволяет вам оставлять комментарии на множестве сайтов, имея лишь один аккаунт на Disqus.com.


Сообщить об ошибке