SPICE модели диодов

Добавлено 11 августа 2017 в 20:10

Глава 3 – Диоды и выпрямители

Программа моделирования схем SPICE в процессе моделирование работы схем обеспечивает и моделирование работы диодов. Модели диодов основаны на характеристиках отдельных устройств, описанных в технических описаниях на конкретные продукты, и характеристиках технологических процессов, которые не указаны в описаниях на устройства. Некоторая информация, взятая из технического описания на 1N4004, приведена на рисунке ниже.

Графики из технического описания на диод 1N4004
Графики из технического описания на диод 1N4004
Табличные данные из технического описания на диод 1N4004
ПараметрЗначениеРазмерность
Максимальный средний выпрямленный ток ID1А
Пиковое повторяющееся обратное напряжение VRRM400В
Пиковый прямой импульсный ток IFSM30А
Общая емкость CT15пФ
Прямое падение напряжения VF1В
Прямой ток IF1А
Максимальный обратный ток IR5мкА
Максимальное обратное напряжение VR400В

Определение диода начинается с имени элемента диода, которое должно начинаться с "d" плюс необязательные символы. Примеры имен элементов диодов: d1, d2, dtest, da, db, d101. Два номера узлов определяют подключение анода и катода, соответственно, к другим компонентам. За номерами узлов следует имя модели, ссылаясь на последующий оператор ".model".

Строка оператора модели начинается с ".model", за которым следует название модели, соответствующее одному или нескольким определениям диода. Затем "d" указывает, что работа диода должна моделироваться. Остальная часть объявления модели представляет собой список дополнительных параметров диода в виде ParameterName=ParameterValue. В примере 1 такие параметры не используются. В примере 2 определены несколько параметров. Список параметров диодов приведен в таблице ниже.

Основная форма:  d[имя] [анод] [катод] [название_модели]
                 .model ([название_модели] d [parmtr1=x] [parmtr2=y] . . .)
 
 Пример1:        d1 1 2 mod1
                 .model mod1 d
 
 Пример2:        D2 1 2 Da1N4004
                 .model Da1N4004 D (IS=18.8n RS=0 BV=400 IBV=5.00u CJO=30 M=0.333 N=2)

Самый простой подход для получения SPICE модели такой же, как и для получения технического описания: посмотрите на сайте производителя. В таблице ниже приведены параметры модели для некоторых диодов. Во втором случае можно создать SPICE модель по тем параметрам, которые указаны в техническом описании. Третий случай, который здесь не рассматривается, – это измерение параметров реального устройства. Затем вычислить, сравнить и подогнать параметры SPICE модели к результатам измерений.

SPICE параметры диодов
ОбозначениеНазваниеПараметрЕдиницы измеренияЗначение по умолчанию
ISISТок насыщения (диодное уравнение)А1E-14
RSRSПаразитное сопротивление (последовательное сопротивление)Ом0
nNКоэффициент эмиссии, от 1 до 21
tDTTВремя переноса зарядас0
CD(0)CJOЕмкость перехода при нулевом смещенииФ0
φ0VJКонтактная разность потенциалов переходаВ1
mMКоэффициент плавности перехода0,5
  0,33 для линейно леггированнного перехода  
  0,5 для лавинного перехода  
EgEGШирина запрещенной зоныэВ1,11
  Si (кремний)эВ1,11
  Ge (германий)эВ0,67
  ШотткиэВ0,69
piXTIТемпературный экспоненциальный коэффициент тока насыщения3,0
  pin переход3,0
  Шоттки2,0
kfKFКоэффициент фликер-шума0
afAFПоказатель степени в формуле фликер-шума1
FCFCКоэффициент емкости обедненной области при прямом смещении0,5
BVBVОбратное напряжение пробояВ
IBVIBVОбратный ток пробояА1E-3

Если параметры диода не указаны, как в первом примере выше, применяются параметры по умолчанию, взятые из таблиц выше и ниже. Это модели по умолчанию диодов в интегральных микросхемах. Они безусловно подходят для предварительной работы и с дискретными устройствами. Для более важной работы используйте SPICE модели, поставляемые производителем, поставщиками ПО SPICE и другими источниками.

SPICE параметры некоторых диодов: sk = Шоттки, Ge = германий, остальные = кремний
ЭлементISRSNTTCJOMVJEGXTIBVIBV
По умолчанию1E-1401000.511.1131m
1N5711 sk315n2.82.031.44n2.00p0.333-0.6927010u
1N5712 sk680p121.00350p1.0p0.50.60.69220-
1N34 Ge200p84m2.19144n4.82p0.3330.750.67-6015u
1N414835p64m1.245.0n4.0p0.2850.6--75-
1N389163n9.6m2110n114p0.2550.6--250-
10A04 10A844n2.06m2.064.32u277p0.333---40010u
1N4004 1A76.9n42.2m1.454.32u39.8p0.333---4005u
1N4004 тех.описание18.8n-2-30p0.333---4005u

В противном случае введите некоторые из параметров, приведенных в техническом описании. Сначала выберите значение для SPICE параметра N между 1 и 2. Это необходимо для диодного уравнения (n). Массобрио в книге “Semiconductor Device Modeling with SPICE” рекомендует «... n, коэффициент эмиссии обычно равен примерно 2». В таблице выше мы видим, что силовые выпрямительные диоды 1N3891 (12 А) и 10A04 (10 А) используют примерно 2. Первые четыре строки в таблице не актуальны, поскольку они представляют собой диод Шоттки, диод Шоттки, германиевый диод и кремниевый диод для малых сигналов, соответственно. Ток насыщения, IS, выводится из диодного уравнения, значения (VD, ID) на графике выше, и N=2 (n в диодном уравнении).

ID = IS (eVD/nVT – 1)

VT = 26 мВ (при температуре 25°C)

n = 2,0

VD = 0,925 В (при 1 А на графике)

1 А = IS (e(0,925 В)/(2)(26 мВ) – 1)

IS = 18,8E-9

Числовые значения IS=18.8n и N=2 приведены в последней строке таблицы выше для сравнения с моделью производителя 1N4004, что значительно отличается. По умолчанию RS установлено в значение 0. Это будет оценено позже. N, IS и RS являются важными статическими параметрами по постоянному току.

Рашид в книге “SPICE for Power Electronics and Electric Power” предлагает, чтобы TT, tD, время перехода, было аппроксимировано из восстанавливаемого заряда QRR, параметра из технического описания (в нашем случае недоступного) и IF, прямого тока.

ID = IS (eVD/nVT – 1) tD = QRR/IF

Мы принимаем TT=0 из-за отсутствия QRR. Хотя было бы разумно взять TT, как у аналогичного выпрямительного диода 10A04, 4.32u. TT диода 1N3891 не подходит, так как выпрямителем с быстрым восстановлением. CJO, емкость перехода при нулевом смещении оценивается по графику зависимости CJ от VR, который приведен выше. Емкость при ближайшем на графике к нулю напряжении составляет 30 пФ при 1 В. Если моделировать отклик на высокоскоростные переходы, как в импульсных источниках питания, то в модели должны быть учтены параметры TT и CJO.

Коэффициент плавности перехода M связан с профилем легирования перехода. Он не содержится в техническом описании устройств. Мы выбираем M = 0.333, что соответствует линейной плавности перехода. Мощные выпрямительные диоды в таблице выше используют более низкие значения M.

Мы берем значения по умолчанию для VJ и EG. Многие другие диоды используют VJ=0.6, что показано в таблице выше. Однако выпрямительный диод 10A04 использует значение по умолчанию, которое мы будем использовать для нашей модели 1N4004 (1N4001 тех. описание в таблице выше). Используйте значение по умолчанию EG=1.11 для кремниевых и выпрямительных диодов. В таблице выше приведены значения для диодов Шоттки и германия. Возьмите XTI=3, стандартный температурный коэффициент IS для кремниевых устройств. Для XTI диодов Шоттки смотрите таблицу выше.

Выдержка из технического описания, показанная на рисунке выше, приводит IR = 5 мкА и VR = 400 В, соответствующие IBV=5u и BV=400, соответственно. Параметры SPICE модели 1n4004, полученные из технического описания, перечислены в последней строке таблицы выше для сравнения с моделью производителя, указанной выше. BV необходим только в том случае, если моделирование производится при обратном напряжении, превышающем обратное напряжение пробоя диода, как в случае со стабилитронами. IBV, обратный ток пробоя, часто опускается, но может быть введен, если приведен и BV.

На рисунке ниже показана схема для сравнения модели производителя, модели, полученной из технического описания, и модели по умолчанию, использующей параметры по умолчанию. Для измерения токов через диоды необходимы три фиктивных источника 0 V. Источник 1 V изменяет своё выходное напряжение от 0 до 1,4 В с шагом 0,2 мВ. Смотрите инструкцию .DC в списке соединений в таблице ниже. DI1N4004 – это модель производителя, а Da1N4004 – модель, созданная нами.

SPICE схема для сравнения модели производителя (D1), модели (D2), рассчитанной по техническому описанию, и модели по умолчанию (D3)
SPICE схема для сравнения модели производителя (D1), модели (D2), рассчитанной по техническому описанию, и модели по умолчанию (D3).

Параметры списка соединений SPICE: (D1) DI1N4004 модель производителя, (D2) Da1N40004 модель, полученная из технического описания, (D3) модель по умолчанию:

*SPICE circuit <03468.eps> from XCircuit v3.20
D1 1 5 DI1N4004
V1 5 0 0
D2 1 3 Da1N4004
V2 3 0 0
D3 1 4 Default
V3 4 0 0
V4 1 0 1
.DC V4 0 1400mV 0.2m
.model Da1N4004 D (IS=18.8n RS=0      BV=400 IBV=5.00u CJO=30
+M=0.333   N=2.0  TT=0)
.MODEL DI1N4004 D (IS=76.9n RS=42.0m  BV=400 IBV=5.00u CJO=39.8p
+M=0.333 N=1.45 TT=4.32u)
.MODEL Default D
.end

Мы сравниваем три модели на рисунке ниже и данные графиков в таблице ниже. VD – это напряжение, подаваемое на диод для сравнения токов модели производителя, нашей расчетной модели и модели диода по умолчанию. Последний столбец "1N4004 график" – это данные из вольт-амперной характеристики из технического описания, которая приведена на рисунке выше, и с которой наши результаты должны совпадать. Сравнение токов трех моделей с последним столбцом показывает, что модель по умолчанию хороша при низких токах; модель производителя хороша при больших токах; а наша рассчитанная по техническому описанию модель лучше всего при токах до 1 А. Точка на 1 А почти идеальна, поскольку расчет IS основан на напряжении диода при 1 А. Наша модель сильно завышает значения тока выше 1 А.

Первое испытание модели производителя, модели по техническому описанию и модели диода по умолчанию
Первое испытание модели производителя, модели по техническому описанию и модели диода по умолчанию
Сравнение модели производителя, модели, рассчитанной по техническому описанию и модели по умолчанию с вольт-амперной характеристикой диода 1N4004 из технического описания
ИндексVDМодель производителяМодель по тех. описаниюМодель по умолчанию1N4004 график
35007.000000e-011.612924e+001.416211e-025.674683e-030.01
40018.002000e-013.346832e+009.825960e-022.731709e-010.13
45009.000000e-015.310740e+006.764928e-011.294824e+010.7
46259.250000e-015.823654e+001.096870e+003.404037e+011.0
50001.000000e-007.395953e+004.675526e+006.185078e+022.0
55001.100000e+009.548779e+003.231452e+012.954471e+043.3
60001.200000e+001.174489e+012.233392e+021.411283e+065.3
65001.300000e+001.397087e+011.543591e+036.741379e+078.0
70001.400000e+001.621861e+011.066840e+043.220203e+0912.

Решение заключается в том, чтобы увеличить RS со значения по умолчанию, которое равно RS=0. Изменение RS от 0 до 8m в модели по техническому описанию приводит к тому, что кривая пересекает 10 А (здесь не показано) при том же напряжении, что и модель производителя. Увеличение RS до 28.6m смещает кривую дальше вправо, как показано на рисунке ниже. Это приводит к более точному соответствию нашей модели с графиком из технического описания (рисунок выше). В таблице ниже показано, что ток 1.224470e+01 А соответствует графику при 12 А. Однако ток при 0.925 В ухудшился с 1.096870e+00 до 7.318536e-01.

Второе испытание для улучшения рассчитаной по техническому описанию модели по сравнению с моделью производителя и моделью по умолчанию
Второе испытание для улучшения рассчитаной по техническому описанию модели по сравнению с моделью производителя и моделью по умолчанию
.model Da1N4004 D (IS=18.8n RS=28.6m  BV=400 IBV=5.00u CJO=30 
+M=0.333   N=2.0  TT=0)
Изменение инструкции RS=0 на RS=28.6m в модели Da1N4004 уменьшает ток при VD=1.4 В до 12.2 А
ИндексVDМодель производителяМодель по тех. описанию1N4004 график
35057.010000e-011.628276e+001.432463e-020.01
40008.000000e-013.343072e+009.297594e-020.13
45009.000000e-015.310740e+005.102139e-010.7
46259.250000e-015.823654e+007.318536e-011.0
50001.000000e-007.395953e+001.763520e+002.0
55001.100000e+009.548779e+003.848553e+003.3
60001.200000e+001.174489e+016.419621e+005.3
65001.300000e+001.397087e+019.254581e+008.0
70001.400000e+001.621861e+011.224470e+0112.

Предлагаемое упражнение для читателя: уменьшить N так, чтобы ток при VD = 0,925 В был восстановлен до 1 А. Это может увеличить ток (12,2 А) при VD = 1,4 В, требуя увеличения RS для уменьшения тока до 12 А.

Стабилитрон. Существует два подхода к моделированию стабилитрона: установка в инструкции модели параметра BV на напряжение стабилитрона или моделирование стабилитрона с подсхемой, содержащей диодный фиксатор уровня, установленный на напряжение стабилитрона. Пример первого подхода устанавливает напряжение пробоя BV в значение 15 для модели стабилитрона 1n4469 на 15 В (IBV необязательно):

.model D1N4469 D ( BV=15 IBV=17m ) 

Второй подход моделирует стабилитрон с подсхемой. Фиксатор уровня D1 и VZ на рисунке ниже моделируют напряжение обратного пробоя 15 В стабилитрона 1N4477A. Диод DR учитывает в подсхеме проводимость стабилитрона при прямом смещении.

Подсхема стабилитрона использует фиксатор уровня (D1 и VZ) в модели стабилитрона
Подсхема стабилитрона использует фиксатор уровня (D1 и VZ) в модели стабилитрона

Туннельный диод. Туннельный диод может быть смоделирован с помощью SPICE подсхемы и пары полевых (JFET) транзисторов.

Диод Ганна. Диод Ганна также может быть смоделирован парой полевых транзисторов.

Подведем итоги

  • Диоды описываются в SPICE с помощью инструкции компонента диода, относящейся к выражению .model. Инструкция .model содержит параметры, описывающие диод. Если параметры не указаны, модель использует значения по умолчанию.
  • Статические параметры по постоянному току включают в себя N, IS и RS. Параметры обратного пробоя: BV, IBV.
  • Для точного динамического моделирования требуются TT и CJO.
  • Рекомендуется использовать модели, предоставляемые производителем.

На сайте работает сервис комментирования DISQUS, который позволяет вам оставлять комментарии на множестве сайтов, имея лишь один аккаунт на Disqus.com.


Сообщить об ошибке