Умножители напряжения

Добавлено 25 марта 2017 в 14:20

Умножитель напряжения представляет собой специальную схему выпрямителя, вырабатывающую выходное напряжение, которое теоретически равно пиковому переменному входному напряжению, увеличенному в целое число раз; например, переменное входное напряжение умноженное в 2, 3 или 4 раза. Таким образом, можно получить 200 Впост из 100 Впик, используя удвоитель, или 400 Впост из учетверителя. Любая нагрузка в реальной схеме снижает эти напряжения.

Применение удвоителя напряжения – это источник постоянного напряжения, способный использовать источник 240 Вперемен или 120 Вперемен. Источник использует переключатель для выбора двухполупериодного мостового выпрямителя для получения примерно 300 Впост из источника 240 Вперемен. Положение 120 В переключателя пересоединяет диодный мост в удвоитель, выдающий примерно 300 Впост из 120 Вперемен. В обоих случаях источник выдает 300 Впост. Такая схема может использоваться в переключаемых источниках питания схем с более низкими напряжениями, например, персонального компьютера.

Однополупериодный умножитель напряжения на рисунке ниже (a) состоит из двух цепей: из фиксатора уровня на рисунке (b) и пикового детектора (однополупериодного выпрямителя) из предыдущей главы, который показан в модифицированной форме на рисунке (c). К пиковому детектору (однополупериодному выпрямителю) был добавлен конденсатор C2.

Однополупериодный умножитель напряжения (a) состоит из (b) фиксатора уровня и (c) однополупериодного выпрямителя
Однополупериодный умножитель напряжения (a) состоит из (b) фиксатора уровня и (c) однополупериодного выпрямителя

Относительно рисунка выше (b), конденсатор C2 заряжается до 5 В (4,3 В с учетом падения напряжения на диоде) во время отрицательного полупериода входного переменного напряжения. Его правый вывод соединен с общим проводом через проводящий диод D2. Его левый вывод заряжается отрицательным пиком входного переменного напряжения. Это работа фиксатора уровня.

Во время положительного полупериода начинает работать однополупериодный выпрямитель на рисунке выше (c). Диод D2 убирается из схемы, так как он смещен в обратном направлении. Конденсатор С2 теперь последовательно соединен с источником напряжения. Обратите внимание, что полярности генератора и C2 направлены в одну сторону и складываются. Таким образом, выпрямитель D1 видит итоговые 10 В на пике синусоиды, 5 В от генератора и 5 В от конденсатора C2.

D1 проводит сигнал v(1) (рисунок ниже), заряжая конденсатор C1 до пика синусоиды, смещенной на 5 Впост (рисунок ниже v(2)). Сигнал v(2) представляет собой сигнал на выходе удвоителя, который стабилизируется на уровне 10 В (8,6 В с учетом падений напряжения на диодах) после нескольких циклов входного синусоидального сигнала.

Удвоитель напряжения: v(4) входной сигнал, v(1) выход  фиксатора уровня, v(2) выход однополупериодного выпрямителя, который является и выходом удвоителя.
Удвоитель напряжения: v(4) входной сигнал, v(1) выход фиксатора уровня, v(2) выход однополупериодного выпрямителя, который является и выходом удвоителя.
*SPICE 03255.eps
C1 2 0 1000p
D1 1 2 diode
C2 4 1 1000p
D2 0 1 diode
V1 4 0 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Двухполупериодный удвоитель напряжения состоит из пары включенных последовательно однополупериодных выпрямителей (рисунок ниже). Соответствующий список соединений показан ниже. Нижний выпрямитель заряжает C1 во время отрицательного полупериода входного сигнала. Верхний выпрямитель заряжает C2 во время положительного полупериода. Каждый конденсатор заряжается до 5 В (4,3 В с учетом падения напряжения на диоде). На выходе в точке 5 последовательно соединенные конденсаторы C1 + C2 дают общее напряжение 10 В (8,6 В с учетом падений напряжения на диодах).

Двухполупериодный удвоитель напряжения состоит из двух однополупериодных выпрямителей, работающих для разных полярностей
Двухполупериодный удвоитель напряжения состоит из двух однополупериодных выпрямителей, работающих для разных полярностей
*SPICE 03273.eps
*R1 3 0 100k
*R2 5 3 100k
D1 0 2 diode
D2 2 5 diode
C1 3 0 1000p
C2 5 3 1000p
V1 2 3 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Обратите внимание, что выходной сигнал v(5) на рисунке ниже достигает своего конечного значения за один период входного сигнала v(2).

Двухполупериодный удвоитель напряжения: v(2) вход, v(3) напряжение в средней точке, v(5) напряжение на выходе

Рисунок ниже показывает построение двухполупериодного удвоителя из пары однополупериодных выпрямителей противоположных полярностей (a). Отрицательный выпрямитель пары перерисовывается для ясности (b). Оба выпрямителя объединяются на (c), используя одну и ту же точку общего провода. На (d) отрицательный выпрямитель переподключается для совместного использования с положительным выпрямителем одного источника напряжения. Это дает источник питания ±5 В (4,3 В с учетом падений напряжения на диодах); хотя между выходами можно измерить 10 В. Точка земли перемещается так, чтобы +10 В были доступны относительно общего провода.

Двухполупериодный выпрямитель: (a) пара выпрямителей, (b) перерисовка, (c) использование общей точки земли, (d) использование общего источника напряжения, (e) перемещение точки земли
Двухполупериодный выпрямитель: (a) пара выпрямителей, (b) перерисовка, (c) использование общей точки земли, (d) использование общего источника напряжения, (e) перемещение точки земли

Утроитель напряжения (рисунок ниже) строится из соединения удвоителя и однополупериодного выпрямителя (C3, D3). Однополупериодный выпрямитель вырабатывает 5 В (4,3 В) в точке 3. Удвоитель обеспечивает 10 В (8,6 В) между точками 2 и 3. В итоге получаем 10 В (12,9 В) на выходной точке 2 относительно земли.

Список соединений показан ниже.

Утроитель напряжения состоит из удвоителя, помещенного над одним звеном выпрямителя
Утроитель напряжения состоит из удвоителя, помещенного над одним звеном выпрямителя
*SPICE 03283.eps
C3 3 0 1000p
D3 0 4 diode
C1 2 3 1000p
D1 1 2 diode
C2 4 1 1000p
D2 3 1 diode
V1 4 3 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Обратите внимание, что v(3) на рисунке ниже поднимается до 5 В (4,3 В) за первый отрицательный полупериод. Входной сигнал v(4) сдвигается на 5 В (4,3 В) из-за напряжения 5 В на однополупериодном выпрямителе. И еще 5 В на v(1) добавляются из-за фиксатора уровня (C2, D2). D1 заряжает C1 (диаграмма v(2)) до пикового значения v(1).

Утроитель напряжения: v(3) однополупериодный выпрямитель, v(4) входной сигнал + 5 В, v(1) фиксатор уровня, v(2) итоговый выходной сигнал
Утроитель напряжения: v(3) однополупериодный выпрямитель, v(4) входной сигнал + 5 В, v(1) фиксатор уровня, v(2) итоговый выходной сигнал

Учетверитель напряжения является комбинацией двух удвоителей и показан на рисунке ниже. Каждый удвоитель обеспечивает 10 В (8,6 В), чтобы при последовательном включении дать в точке 2 напряжение 20 В (17,2 В) относительно общего провода.

Список соединений показан ниже.

Учетверитель напряжения состоит из двух удвоителей, включенных последовательно с выходом в точке 2
Учетверитель напряжения состоит из двух удвоителей, включенных последовательно с выходом в точке 2
*SPICE 03441.eps
*SPICE 03286.eps
C22 4 5 1000p
C11 3 0 1000p
D11 0 5 diode
D22  5 3 diode
C1 2 3 1000p
D1  1 2 diode
C2 4 1 1000p
D2  3 1 diode
V1 4 3 SIN(0 5 1k)
.model diode d
.tran 0.01m 5m
.end

Диаграммы напряжений в учетверителе показаны на рисунке ниже. Доступны два выхода постоянного напряжения: v(3), выход удвоителя, и v(2), выход учетверителя. Некоторые из промежуточных напряжений показывают, что входная синусоида (не показана) с амплитудой 5 В последовательно фиксируется на более высокие уровни: v(5), v(4) и v(1). Строго говоря, v(4) не является выходом фиксатора уровня. Это просто источник переменного напряжения, соединенный последовательно с v(3), выходом удвоителя. Тем не менее, v(1) является зафиксированной версией v(4).

Учетверитель напряжения: Постоянное напряжение доступно в v(3) и v(2). Диаграммы промежуточных напряжений: фиксаторы v(5), v(4), v(1)
Учетверитель напряжения: Постоянное напряжение доступно в v(3) и v(2). Диаграммы промежуточных напряжений: фиксаторы v(5), v(4), v(1)

На данный момент необходимо сделать несколько замечаний относительно умножителей напряжения. Параметры, используемые в примерах схем (V = 5В 1кГц, C = 1000 пФ), не обеспечивают большие токи, а только микроамперы. Кроме того, не были приведены резисторы нагрузки. Нагрузка уменьшает напряжения, показанные выше. Если схема управляется низковольтным источником с частотой в килогерцы, как в примерах, то конденсаторы обычно составляют от 0,1 до 1,0 мкФ, чтобы на выходе были доступны миллиамперы. Если на умножители подается напряжение с частотой 50/60 Гц, конденсатор составляет от нескольких сотен до нескольких тысяч микрофарад, чтобы обеспечить выходной ток в сотни миллиампер. Если вы работаете с сетевым напряжением, то обратите внимание на полярности и номиналы напряжений конденсаторов.

Наконец, любой источник питания, подключенный напрямую (без трансформатора), опасен для экспериментатора и тестового оборудования. Промышленные источники, работающие напрямую от сети, безопасны, поскольку опасные схемы находятся в корпусе для защиты пользователя. При макетировании этих схем с электролитическими конденсаторами любых напряжений, если полярность конденсатора меняется на противоположную, то конденсатор взрывается. Такие схемы должны быть закрыты защитным экраном.

Умножитель напряжения из каскадно включенных однополупериодных выпрямителей произвольной длины известен как умножитель Кокрофта-Уолтона и показан на рисунке ниже. Этот умножитель используется, когда требуется высокое напряжение при малом токе. Его преимущество перед обычным источником питания заключается в том, что не требуется дорогостоящий трансформатор напряжения.

Умножитель напряжения Кокрофта-Уолтона  на 8, выход в точке v(8)
Умножитель напряжения Кокрофта-Уолтона на 8, выход в точке v(8)
D1 7 8 diode
C1 8 6 1000p
D2 6 7 diode
C2 5 7 1000p
D3 5 6 diode
C3 4 6 1000p
D4 4 5 diode
C4 3 5 1000p
D5 3 4 diode
C5 2 4 1000p
D6 2 3 diode
D7 1 2 diode
C6 1 3 1000p
C7 2 0 1000p
C8 99 1 1000p
D8 0 1 diode
V1 99 0 SIN(0 5 1k)
.model diode d
.tran 0.01m 50m
.end

Пара диодов и конденсаторов слева от узлов 1 и 2 на рисунке выше составляют однополупериодный удвоитель. Вращение диодов на 45° против часовй стрелки, а нижний конденсатор на 90° делают их похожими на первый рисунок (a). Четыре секции удвоителей включаются каскадно для получения теоретического коэффициента умножения 8. Узел 1 имеет форму сигнала фиксатора уровня (не показана), синусоида сдвинута вверх на 1x (5В). Остальные узлы с нечетными номерами – это синусоиды, последовательно фиксируемые на более высоких напряжениях.

Узел 2, выход первого удвоителя, равен удвоенному постоянному напряжению, v(2) на рисунке ниже. Последующие четные узлы заряжаются последовательно более высокими напряжениями: v(4), v(6), v(8).

Формы напряжений в умножителе Кокрофта-Уолтона (x8). Выходное напряжение v(8)
Формы напряжений в умножителе Кокрофта-Уолтона (x8). Выходное напряжение v(8)

Без учета падений напряжения на диодах, каждый удвоитель дает 2Vin или 10 В; реально, с учетом падений напряжения на двух диодах, (10 – 1,4) = 8,6 В. В общей сложности 4 удвоителя ожидаемо дают 4·8,6=34,4 В из 40 В. Если посмотреть на рисунок выше, v(2) соответствует ожиданиям; однако, v(8) < 30 В, вместо ожидаемых 34,4 В. Недостаток умножителя Кокрофта-Уолтона заключается в том, что каждая дополнительная ступень добавляет меньше предыдущей. Таким образом, существует практическое ограничение в добавлении ступеней. Это ограничение можно преодолеть модификацией базовой схемы. Также обратите внимание на шкалу времени длиной 40 мс по сравнению с 5 мс для предыдущих схем. Чтобы напряжения достигли предельных значений в этой схеме, требуется 40 мс.

В список соединений выше добавлена команда ".tran 0.010m 50m", чтобы расширить время симуляции до 50 мс; хотя на графике показаны только 40 мс.

Умножитель Кокрофта-Уолтона служит более эффективным источником высокого напряжения для трубок фотоэлектронных умножителей, требующих напряжение до 2000 В. Кроме того, трубка имеет множество динодов, выводов, которые требуют подключения к четным узлам с более низкими напряжениями. Рад удвоителей умножителя заменяет собой нагревающийся резистивный делитель напряжения, используемый в предыдущих конструкциях.

Умножитель Кокрофта-Уолтона, работающий от сети переменного тока, обеспечивает высокое напряжения для "ионных генераторов" для нейтрализации электростатического заряда и для очистителей воздуха.

Подведем итоги

  • Умножители напряжения выдают постоянное напряжение, равное умноженному (на 2, 3, 4 и т.д.) пиковому значению входного переменного напряжения.
  • Самый базовый умножитель – это однополупериодный удвоитель.
  • Двухполупериодный удвоитель – это лучшая схема удвоителя.
  • Утроитель представляет собой однополупериодный удвоитель и обычный выпрямительный каскад (пиковый детектор).
  • Учетверитель – это пара однополупериодных удвоителей.
  • Длинная цепочка однополупериодных удвоителей известна как умножитель Кокрофта-Уолтона.

Теги

ДиодОбучениеУмножитель напряженияЭлектроника

На сайте работает сервис комментирования DISQUS, который позволяет вам оставлять комментарии на множестве сайтов, имея лишь один аккаунт на Disqus.com.

В случае комментирования в качестве гостя (без регистрации на disqus.com) для публикации комментария требуется время на премодерацию.